cerca.vert valori a pari merito

[marcoc]

buongiorno a tutti,
ho un semplice elenco con in col.A il numero di presenze e in col.B il nome della persona.
L'elenco è ordinato in maniera crescente in base a un un altro parametro, presente in col.C.

Sto cercando una formula che mi riporti i valori maggiori; sto usando
=GRANDE(PRESENZE!$B$2:$B$1000;1) per il primo
=GRANDE(PRESENZE!$B$2:$B$1000;2) per il secondo
=GRANDE(PRESENZE!$B$2:$B$1000;3) per il terzo
poi con un cerca.vert associo la relativa persona ai valori.

In caso di più valori uguali in col.A, il cerca.vert mi duplica nome associato al primo valore che trova.
Come posso fare per evitare questa cosa e trovare tutti i nomi che mi servono, compresi i "parimeriti"?

[Anthony47]

Quale versione di office usi?

[marcoc]

office standard 2013

[Anthony47]

Se avevi Office 365 era tutta un'altra cosa...

Nell'ipotesi che i tuoi valori contengano max 2 decimali (avrei fatto meglio a chiederti che dati erano...) prova questa formula:

Codice: Seleziona tutto

=RESTO(GRANDE(100*(PRESENZE!$B$2:$B$1000)+RIF.RIGA($B$2:$B$1000)/10000;1);1)*10000

Da confermare con Contr-Maiusc-Enter
Ti dara' LA RIGA dove compare l'ultimo valore piu' grande; modificando il primo 1 in 2-3 puoi ottenere il secondo e il terzo

Col numero riga poi sei in grado di prendere dalla tabella tutti i valori che ti servono

Ciao

[marcoc]

grazie Anthony, ma mi manca l'ultimo passaggio...
una volta che mi ha trovato che il primo è in riga (es.) 33, come faccio a dirgli di riportarmi il nome presente nella cella B33?

[Anthony47]

Usa ad esempio INDICE...
Se il numero riga e' in D2:

Codice: Seleziona tutto

=INDICE(B$1:B$1000;ARROTONDA(D2;0))

Ho usato ARROTONDA perche' e' facile che l'operazione restituisca un numero (di riga) con decimali

Se devi prelevare piu' colonne, ricorda che INDICE ti puo' restituire piu' colonne della matrice di origine; es

Codice: Seleziona tutto

=INDICE(B$1:D$1000;ARROTONDA(D2;0);0)

Resitituisce l'intera riga (usa Contr-Maiusc-Enter per sfruttare il risultato

Codice: Seleziona tutto

=INDICE(B$1:D$1000;ARROTONDA(D2;0);{1\3})

Restituisce le colonne 1 e 3

Ciao