Hyperlink tra celle uguali in fogli differenti

[gabally]

buondì a tutti,

ecco il mio dilemma: supponiamo di avere due fogli: Foglio1 e Foglio2
nel Foglio1, in B2, ho il numero 123456 (no formula, no testo), lo stesso numero è presente in , diciamo, A15 del Foglio2 (ma la settimana prossima potrebbe essere in Ax con "x" compreso tra 2 e 1000)
io vorrei, cliccando con il mouse sulla cella B2 del Foglio1, andare automaticamente nel Foglio2, colonna A, nell'unica cella contenente il numero presente in B2 del Foglio1.

Ho provato con il collegamento ipertestuale ma mi da solo la possibilità di selezionare una cella specifica del Foglio2 e invece a me serve un qualcosa di "dinamico".

La stessa operazione dovrebbe essere ripetuta per tutte le celle non vuote della colonna B del Foglio1

secondo voi si può fare? e se si, come?

grazie in anticipo a tutti

Utilizzo Excel 2010

[Marius44]

Ciao
se i numeri in Foglio2 NON SONO RIPETUTI si potrebbe inserire nell'evento Worksheet_SelectionChange la funzione CERCA.VERT

Comunque è sempre meglio allegare un file.
Ciao,
Mario

[Anthony47]

Prova con questa macro, che non usa hyperlink:

Codice: Seleziona tutto

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim tSheet As Worksheet
'
If Target.Column <> 2 Then Exit Sub
Set tSheet = Sheets("Foglio2")          '<<< Il foglio su cui cercare
If Application.WorksheetFunction.CountIf(tSheet.Cells, Target.Value) > 0 Then
    tSheet.Select
    ActiveSheet.Cells.Find(What:=Target.Value, After:=ActiveSheet.Range("A1"), LookIn:=xlValues, LookAt _
        :=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
        False, SearchFormat:=False).Activate
Else
    Beep
    MsgBox ("Non trovato")
End If
Cancel = True
End Sub


Va inserita nel "Modulo di codice" del foglio di partenza: tast dx sul tab col nome del foglio, scegli Visualizza codice; inserisci il codice nel frame di dx.
Poi torna sul foglio iniziale e fai doppioclick sulla cella contenente il valore da cercare.

E se cosi' non risolvi allora segui il suggerimento di Marius e allega un file di esempio.

Ciao

[gabally]

WOW

Funziona perfettamente !!!

Grande Anthony, Grazie !

[gabally]

MI spigheresti come funziona?

Vorrei "imparare a fare il pane" invece che chiedere una pagnotta

almeno la prossima volta non dovrò più chiedere

[Anthony47]

Funziona che la macro si attiva sull'evento doppioclick.
Se la colonna non e' la 2 la macro non fa nulla.
Se colonna=2, se il valore su cui si e' fatto doppioclick esiste nel secondo foglio allora si esegue il comando Trova; altrimenti esce un messaggio "Non trovato"

Per arrivare a fare il pane comincia a registrare qualche piccola macro e guarda il codice che viene prodotto; per le prime istruzioni su come registrare una macro:
viewtopic.php?f=26&t=103893&p=622593#p622593

Ciao