excel 2013 - da 1 colonna a + colonne

[femon]

Salve a tutti, ho cercato sul forum, ma non ho trovato risposta a questo problema:

Ho un file excel con 1 colonna lunga circa 2200 righe, vorrei stamparla su dei fogli A4 orizzontali in modo da avere la colonna lunga distribuita su più colonne nello stesso foglio (circa 15 colonne) ed ogni colonna lunga max 45 righe in modo da stampare al max 4 fogli.
E' possibile?
Grazie mille per l'aiuto.
Federico.

[Anthony47]

Prova con questa macro:

Codice: Seleziona tutto

Sub ToManyCols()
Dim I As Long, MaxR As Long, MaxC As Long, SList As Range
Dim J As Long, K As Long, PagN As Long, lEnd As Boolean
'
MaxR = 45                   '<<< Le righe compilate per pagina
MaxC = 5                    '<<< Le colonne compilate per pagina
Set SList = Range("B2")     '<<< La cella dove comincia l'elenco
'
Sheets.Add after:=ActiveSheet
For PagN = 0 To 100
    For I = 0 To MaxC - 1
        SList.Offset(MaxR * (I + PagN * MaxC), 0).Resize(MaxR, 1).Copy _
           Cells(1 + (MaxR + 2) * PagN, I + 1)
        If Application.WorksheetFunction.CountA(SList.Offset(MaxR * (I + PagN * MaxC), 0).Resize(MaxR, 1)) = 0 Then
            lEnd = True
            Exit For
        End If
    Next I
    ActiveSheet.HPageBreaks.Add before:=Cells((MaxR + 2) * (PagN + 1), 1)
    If lEnd Then Exit For
Next PagN
End Sub


Va inserita in un Modulo standard del vba; le righe marcate <<< sono da personalizzare come da commento.

Poi va lanciata dopo aver attivato il foglio con il lungo elenco.

Verra' creato un nuovo foglio che conterra' per ogni pagina le righe e le colonne indicate (salvo che la stampante o la carta o le impostazioni di stampa non impongano un limite inferiore)

Ciao

[femon]

Grazie mille Anthony funziona come desideravo!!!!
Grazie e gentilissimo.
Federico.