Ripartire quota a varie celle

[contiend]

Ciao,
avrei bisogno di una mano per trovare una formula che mi permetta di fare questa procedimento.

Ho 5 celle in tre colonne.
Ad ogni cella in COL A e COL B, ho indicato un numero (una previsione di spesa) + la percentuale dedicata a questa previsione di spesa.

Il totale, in questo caso è 100 € per farla semplice.

COL A // COL B
20 % - 20 €
30 % - 30 €
40 % - 40 €
5 % - 5 €
5 % - 5 €

A questo punto in COLONNA C1 scriverò nella cella adiacente a € 20, il numero reale speso. Ad esempio 30 €, superiore
In questo momento la colonna B dovrebbe aggiornarsi INDICANDOMI lui quanto posso spendere, ripartendo nel modo corretto i soldi (e immagino aggiornando anche le percentuali).

Non so se ho spiegato bene ^^

COL A e B sono una previsione.

Ma nel momento che sforo alla prima riga, o alla quarta riga, non c'è un ordine esatto nella quale io inserisco i dati, la formula dovrebbe ricalcolarmi la percenutale ed indicarmi, per le altre quattro voci, quanto posso spendere.

Aggiornando poi la colonna C con un altro dato (reale spesa), la formula mi dirà, per i rimanenti 3 celle vuote di COL C, quanto posso spendere.

Stesso discorso se invece pago di meno.
E quindi nelle righe successiva mi dovrebbe ripartire una spesa maggiore.

Sapete consigliare qualcosa?
grazie

[wallace&gromit]

Ciao,
penso che serva qualche colonna in più.
Da A2 a A6 abbiamo le percentuali di partenza, che devono restare immutate perché ci servono per capire le proporzioni corrette tra le varie voci.
In B1 vi è l'importo totale prefissato (100 o altro valore che si può modificare).
Da B2 a B6 viene calcolato il budget teorico a disposizione con la formula messa in B2 e trascinata in basso

Codice: Seleziona tutto

=A2*B$1

Da C2 a C6 vi sono celle libermente compilabili con le spese reali.

In D2 mettiamo la formula che copiamo in basso:

Codice: Seleziona tutto

=SE(C2="";A2/MATR.SOMMA.PRODOTTO(A$2:A$6;--(C$2:C$6=""));"")

Questa ricalcola le percentuali secondo le proporzioni in colonna A ma solo per le righe ancora vacanti.

In E1 facciamo calcolare il nuovo budget (B1 meno somma di C2:C6).
E in E2 mettiamo la formula che copiamo in basso:

Codice: Seleziona tutto

=SE(D2<>"";D2*E$1;"")

in questo modo vedremo visualizzati in colonna E gli importi di spesa previsti, aggiornati di volta in volta.

Qui trovi il mio esempio:
http://www.filedropper.com/formulecalcolobudgetconprevisioni

[Anthony47]

Azz... Wallace (o forse Gromit) mi ha preceduto, ma pubblico lo stesso questa ipotesi con meno colonne

Ribadisco che ovviamente in colonna B non puoi pensare di avere contemporaneamente il risultato di una formula (il budget) e un dato (la spesa reale) inserito da tastiera...
Devi quindi almeno pensare di usare la colonna C per la Spesa reale e aggiornare man mano che hai dei consuntivi il budget rimanente sulle voci ancora da consuntivare

Ad esempio:


Compilato il consuntivo della prima voce (una qualsiasi dell'elenco), automaticamente le previsioni per le voci residue vengono rimodulate in funzione della spesa residua.

Nella tabella mostrata, questo si ottiene inserendo in B2 la formula

Codice: Seleziona tutto

=SE(C2=0;($A$1-MATR.SOMMA.PRODOTTO($C$2:$C$6;--(RIF.RIGA($C$2:$C$6)<>RIF.RIGA(C2))))/MATR.SOMMA.PRODOTTO($A$2:$A$6;--(C$2:$C$6=0))*A2;$A$1*A2)

Poi si copia verso il basso.

A1 contiene il budget complessivo

Ciao

[contiend]

Siete qualcosa di MAGICO
Grazie ad entrambi.
Super.

[Anthony47]

Tutto a un tratto mi sono reso conto che la mia formula (B2 da copiare poi verso il basso) puo' essere semplificata in

Codice: Seleziona tutto

=SE(C2=0;($A$1-MATR.SOMMA.PRODOTTO($C$2:$C$6))/MATR.SOMMA.PRODOTTO($A$2:$A$6;--(C$2:$C$6=0))*A2;$A$1*A2)


Ciao