Trova 4005 Coppie Numeri In Archivio

[scanacc]

Come dovrei fare per mettere i totali nella successive colonne del foglio Archivio e indicando i sub totali per ruota?
Praticamente in corrispondenza delle varie combinazioni avere una cosa del genere
Esempio

- n' - tot * RM TO BA NA MI GE FI PA VE CA
1 2 - 36 * 0 10 2 10 10 1 0 3 0 0
1 3 - 24 * 5 5 1 0 10 2 0 0 1 0
1 4 - XX * etc etc
etc etc

[scanacc]

Sono incolonnati male ma spero di essermi spiegato sufficientemente

[scanacc]

Vorrei inoltre chiedere a Ikwae dove posso trovare le stringhe che ha inserito nell'archivio e se è possibile avere anche quelle precedenti

[scanacc]

In pratica a me servirebbe una cosa molto semplice.
Dato il Foglio ESTRAZIONI che contiene tutte le estrazioni, vorrei che nel Foglio STATISTICHE, fossero raggruppati i TOTALI delle uscite all’interno delle loro caselle.
Allego FILE DI ESEMPIO

https://wetransfer.com/downloads/c4d86abd12092c17a5830c6c583fcd8720201025125211/5f13ddbc0b92352ad346455779d7faae20201025125255/759629

[ikwae]

Ciao scanacc ... con tutta la mia buona volontà non ho la più pallida idea di cosa tu voglia con " raggruppati i TOTALI" se puoi spiegarlo come se io fossi un bimbo di 6 anni forse capisco, ma non garantisco, comunque se dovessi capire qualche cosa, cercherò in rete qualche soluzione per te. Per le stringhe(o cinquine?) che cerchi sono disponibile a dare tutto quello che ho ma a capire a quale stringe ti riferisci.... Cordialmente ikwae

[Anthony47]

Per scanacc: Ti sei agganciato a una discussione aperta da ikwae che aveva tutt'altro argomento (viewtopic.php?f=26&t=111580&p=655355#p655300); quindi l'ho sganciata trasformandola in discussione a sé stante.
Per ikwae: Credo che scanacc voglia compilare la tabella degli ambo impostata in foglio Statistiche...
Se e' cosi', allora dovrebbe aiutare questa macro:

Codice: Seleziona tutto

Sub AllocAmbi()
Dim OArr(1 To 4005, 1 To 1), wArr, IArr(1 To 90, 1 To 90, 1 To 11)
Dim LastR As Long, I As Long, J As Long, K As Long, oInd As Long, L As Long
'
Sheets("Estrazioni").Select
LastR = Cells(Rows.Count, "A").End(xlUp).Row
For L = 0 To 10
    wArr = Range("B2").Offset(0, L * 5).Resize(LastR - 1, 5).Value
    Erase OArr
    For I = 1 To UBound(wArr)
        For J = 1 To 4
            For K = J + 1 To 5
                    If wArr(I, J) < wArr(I, K) Then
                    oInd = (90 - wArr(I, J) / 2) * (wArr(I, J) - 1) + wArr(I, K) - wArr(I, J)
                    OArr(oInd, 1) = OArr(oInd, 1) + 1
                ElseIf wArr(I, J) > wArr(I, K) Then
                    oInd = (90 - wArr(I, K) / 2) * (wArr(I, K) - 1) + wArr(I, J) - wArr(I, K)
                    OArr(oInd, 1) = OArr(oInd, 1) + 1
                End If
            Next K
        Next J
    Next I
    Sheets("Statistiche").Range("F5").Offset(0, L).Resize(4005, 1) = OArr
Next L
MsgBox ("Completato...")
End Sub


Va messa in un modulo standard del vba.
Presuppone che la sequenza delle ruote in Statistiche sia la stessa che in Estrazioni
Rimane, in Estrazioni, da compilare la colonna TOT; ma qui basta una formula (inserita in E5 e copiata verso il basso)

Ciao

[ikwae]

Grazie Anthony per la precisazione...
Per scanacc puoi allegare il tuo file su File Dropper perché il mio Linux si rifiuta di accettare al tuo link "termini di servizio"
Cordialmente ikwae

[scanacc]

Grazie Antony, non pensavo potesse essere così veloce.
Vedo però che ci sono alcuni spazi completamente vuoti.
Per esempio gli ambi che vanno dal 2-10 al 2-19 non sono riportati. così come dal 3-10 al 3-29, dal 4-10 al 4-39, dal 5-10 al 5-49 dal 6-10 al 6-59 etc etc.
Penso che ci sia qualcosa che non va.
Grazie comunque

[scanacc]

In realtà ho copiato i dati su un nuovo FILE excel e dopo aver convertito i dati in numeri, tutto sembra andare in modo perfetto.

[Anthony47]

Si, infatti il problema e' che nel tuo file quei "numeri" sono in realta' testi che mandano in tilt un calcolo nel caso di "numeri" di una sola cifra...
Bisognerebbe aggiungere quest due istruzioni in questa posizione:

Codice: Seleziona tutto

            For K = J + 1 To 5
                wArr(I, J) = CLng(wArr(I, J))       '+++QUESTA
                wArr(I, K) = CLng(wArr(I, K))       '+++QUESTA
                If wArr(I, J) < wArr(I, K) Then


Oppure, come hai fatto, convertire in "numeri" sul foglio Estrazioni

Ciao

[scanacc]

Grazie Antony.
Scusa ora se approfitto.
Potrei avere (nelle colonne inserite in STATISTICHE1 che ho aggiunto) anche i totali per i singoli numeri?
Grazie infinite
https://we.tl/t-f0hziGLKpO

[Anthony47]

Immagino che intenda la conta delle uscite dei singoli numeri...
La nuova macro:

Codice: Seleziona tutto

Sub AllocAmbi2()
Dim OArr(1 To 4005, 1 To 1), wArr, IArr(1 To 90, 1 To 90, 1 To 11)
Dim LastR As Long, I As Long, J As Long, K As Long, oInd As Long, L As Long
Dim StArr(1 To 90, 1 To 1)
'
Sheets("Estrazioni").Select
LastR = Cells(Rows.Count, "A").End(xlUp).Row
For L = 0 To 10
    wArr = Range("B2").Offset(0, L * 5).Resize(LastR - 1, 5).Value
    Erase OArr
    Erase StArr
    For I = 1 To UBound(wArr)
        For J = 1 To 4
            For K = J + 1 To 5
                wArr(I, J) = CLng(wArr(I, J))       '+++QUESTA
                wArr(I, K) = CLng(wArr(I, K))       '+++QUESTA
                If wArr(I, J) < wArr(I, K) Then
                    oInd = (90 - wArr(I, J) / 2) * (wArr(I, J) - 1) + wArr(I, K) - wArr(I, J)
                    OArr(oInd, 1) = OArr(oInd, 1) + 1
                ElseIf wArr(I, J) > wArr(I, K) Then
                    oInd = (90 - wArr(I, K) / 2) * (wArr(I, K) - 1) + wArr(I, J) - wArr(I, K)
                    OArr(oInd, 1) = OArr(oInd, 1) + 1
                End If
            Next K
        Next J
        For J = 1 To 5
            If wArr(I, J) > 0 Then
                StArr(wArr(I, J), 1) = StArr(wArr(I, J), 1) + 1
            End If
        Next J
    Next I
    Sheets("Statistiche").Range("F5").Offset(0, L).Resize(4005, 1) = OArr
    Sheets("Statistiche1").Range("C5").Offset(0, L).Resize(90, 1) = StArr
Next L
MsgBox ("Completato...")
End Sub

Non avrai difficolta' a individuare le aggiunte

Ciao

[scanacc]

Grande Anthony.