Thunderbird, inviare mail con attachments

[Maury170419]

Ciao a tutti
E il mio problema e questo :
Con questa procedura :

Codice: Seleziona tutto

Const SW_SHOWNORMAL As Long = &H1

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

Sub Invio_Email_thunderbird()
Dim strCommand As String, strSubject As String, strBody As String
Dim strFilePath As String

    strSubject = "Subject"
    strFilePath = Application.ActiveWorkbook.FullName
    strBody = Foglio1.Cells(3, 4).Value & ""
   
    'use only one of the following thunderbird path, depending on your operating system:
   ' strCommand = "C:\Program Files (x86)\Mozilla Thunderbird\thunderbird"
   ' strCommand = "C:\Program Files (x64)\Mozilla Thunderbird\thunderbird"
    strCommand = "C:\Program Files\Mozilla Thunderbird\thunderbird"
   
strCommand = strCommand & " -compose " & "to=" & Cells(1, "J") & "," & "cc=" & "," & _
"subject=" & Foglio1.Cells(2, 4).Value & "" & "," & "body=" & strBody & ", " & "attachment=" & strFilePath

Call Shell(strCommand, vbNormalFocus)

'L'e-mail con Allegato Dovrebbe essere di Questo Tipo
'.attachments.add thisworkbook.path = "Allegati\1.1.word1.docx"
'Solo Che Se Lo Metto Cosi Comprensivo Di ( .Display ) Finale
'Non mi Funziona Più Nulla In Quanto Continua A Darmi Errore

End Sub


Riesco ad Aprire il Mio Thunderbird di posta elettronica
Però a differenza di ( Outlook ) non riesco ad usare il Famigerato ( attachments.add )
Compreso il ( .Display) come funzione finale
In quanto se ometto queste due funzioni , il programma funziona alla grande
Se li inserisco nella procedura
La procedura stessa si Interrompe.
Qualcuno saprebbe dirmi il perché e come apportare le dovute modifiche Grazie
Saluti da A.Maurizio

[Anthony47]

Non ho trovato le specifiche della Command Line di Thunderbird, ma certamente i parametri vanno passati tra "virgolette semplici", anche se sono vuoti.
E poi tutta la riga va racchiusa tra virgolette.
Infine, provando e riprovando, l'argomento "attachment" va inserito prima del "body".

A me ha funzionato così:

Codice: Seleziona tutto

Sub Invio_Email_thunderbird()
Dim strCommand As String, strSubject As String, strBody As String
Dim strFilePath As String
'
'strFilePath = Application.ActiveWorkbook.FullName
strFilePath = "D:\DDownloads\4LUCA_FILE-DUE.xlsx"                           '<<< L'allegato che vuoi
strBody = Cells(3, 4).Value                                                 '<<< Il testo
'
strCommand = "C:\Program Files (x86)\Mozilla Thunderbird\thunderbird.exe"   '<<< Applicazione Thunderbird
'Segue la composizione della stringa di comando:
strCommand = strCommand & " -compose " _
  & """" & "to='" & Cells(1, "J") & "'," _
  & "cc=''" & "," _
  & "subject='" & Cells(2, 4).Value & "'," _
  & "attachment='" & strFilePath & "'," _
  & "body='" & strBody & "', " & """"
Call Shell(strCommand, vbNormalFocus)
'
End Sub


Questo codice apre la finestra di composizione del messaggio, completo di destinatario, subject, l'allegato, il body della mail; pronto per l'invio.
Ho scomposto la composizione della riga di comando su tante righe vba per visualizzare meglio come i vari parametri vengono assemblati.

La riga di comando che viene cosi' creata:

Codice: Seleziona tutto

C:\Program Files (x86)\Mozilla Thunderbird\thunderbird.exe -compose "to='anthony@dominio.com',cc='',subject='Un Subject',attachment='D:\DDownloads\4LUCA_FILE-DUE.xlsx',body='Caro amico ti scrivo...', "


Ciao

[Maury170419]

Grazie di Tutto Anthony47
Come sempre sei un Genio
Anche sé mi sorge una domanda alquanto banale
Che e questo :
Tu hai riportato la funzione ( Attachments ) all'interno della procedura
Mentre io Usando il Programma di ( Outlook ) che ho scritto in questo modo :

Codice: Seleziona tutto

Sub Invioemail()
    Dim OutApp As Object
    Dim OutMail As Object
    Dim EmailAddr As String
    Dim Subj As String
    Dim BodyText As String

sAllegato = ThisWorkbook.Path & "\Utility\1.pdf2.pdf"

    EmailAddr = Foglio1.Range("H1").Value & ""  '<<< inserire  indirizzi
    Subj = Foglio1.Range("A4").Value & ""

    BodyText = Foglio1.Range("A5").Value & "" & Chr(13) & _
    "Aggiungo Allegato ." & Chr(13) & Foglio1.Range("H21").Value & ""

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With OutMail
    .To = EmailAddr
    .CC = ""
    .BCC = ""
    .Subject = Subj
    .body = BodyText
    .Attachments.Add sAllegato
    .display 'or use .send
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
    End Sub


Come Vedi lo inserito nella parte finale del Programma ; Però funziona comunque.
Pertanto la mia forma di pensiero e questa:
Non è che cosi facendo e come se si tentasse di prendere in giro la procedura stessa ?
Tutto qui !
Grazie ancora del tuo Aiuto Come Sempre Ribadisco Che Sei Un Grande .
Saluti da A.Maurizio

[Anthony47]

Le modalita' di accesso a Outlook non hanno niente in comune con l'accesso a Thunderbird:
-nel primo caso si accede agli "oggetti" di Outlook usando la libreria vba di Outlook; nel secondo l'accesso avviene tramite una riga di comandi che il progettista di Thinderbird ha reso disponibile, e che consente di inserire in una riga il comando "compila mail" con in sequenza le informazioni fondamentali.

Quindi due procedure ben diverse, che hanno in comune solo il fatto che si parla di email

Ciao

[Maury170419]

In Pratica sia che tu usi Outlook e il suo Vba
Ho Thurderbird si deve interagire con il suo Compilatore
Anche per questa Delucidazione Ti Invio i miei Più Sinceri Grazie di Tutti