Calcolo orario con recupero

[Flash30005]

Ciao Anthony

Ho realizzato un semplice calcolo orario lavorativo ma credo di aver usato un "formulone" che penso si possa semplificare.
Allora, in A9 inserisco l'orario di entrara in hh:mm in B9 quello di uscita in C9 eventuale pausa (00:45 o 00:30) in D9 ho inserito questa formula per le ore effettivamente lavorate:

Codice: Seleziona tutto

=ORARIO.VALORE(INT(((ORA(B9)+SE(ORA(A9)>ORA(B9);24;0))*60+INT(MINUTO(B9)/15)*15-(ORA(A9)*60+INT(MINUTO(A9)/15)*15))/60)&":"&(((ORA(B9)+SE(ORA(A9)>ORA(B9);24;0))*60+INT(MINUTO(B9)/15)*15-(ORA(A9)*60+INT(MINUTO(A9)/15)*15))/60-INT(((ORA(B9)+SE(ORA(A9)>ORA(B9);24;0))*60+INT(MINUTO(B9)/15)*15-(ORA(A9)*60+INT(MINUTO(A9)/15)*15))/60))*60)-C9-ORARIO.VALORE("00:"&SE(RESTO(MINUTO(A9);15)>0;1;0)*15)

La formula calcola l'orario tenendo conto dei quarti d'ora effettivamente lavorati.
I minuti di recupero funzionano così:
se entro alle 8 e 5 minuti devo recuperare 15 minuti e non 5 minuti (un intero quarto d'ora) alla fine della giornata quindi con entrata alle ore 8:05, uscita alle 16:58 con pausa di 45 minuti devo ottenere 7 ore e 45 minuti lavorati e non 8 ore.
Come dicevo la mia formula funziona ma mi sembra "esagerata"
(mentre scrivo mi è venuta l'idea che forse è meglio calcolare l'orario in quarti d'ora?)

Ciao

[pietrol]

Ciao flash30005

non sono sicuro di avere correttamente interpretato le tue indicazioni, prova se ti va bene questa formula, in caso contrario postami l'esempio in cui il calcolo fallisce e quale dovrebbe essere il risultato corretto.

Codice: Seleziona tutto

=ARROTONDA.DIFETTO((SE(B9<A9;B9+1;B9)-A9);1/96)-C9


ciao
pietrol

[tutamimetica]

Io l'avrei risolto come da allegato.
Ciao Tuta

[Flash30005]

Ciao flash30005

non sono sicuro di avere correttamente interpretato le tue indicazioni, prova se ti va bene questa formula, in caso contrario postami l'esempio in cui il calcolo fallisce e quale dovrebbe essere il risultato corretto.

Codice: Seleziona tutto

=ARROTONDA.DIFETTO((SE(B9<A9;B9+1;B9)-A9);1/96)-C9


ciao
pietrol

Mi sembrava un po' troppo semplice la tua formula...
Infatti, se io inserisco entrata 8:02 (in A9, perdo 15 minuti da recuperare) e uscita 16:02 (in B9) e pausa 0:00 (per semplificare) la tua formula mi dà 8 ore effettive mentre le 8 ore effettive sarebbero completate alle 16:15 (8 entrata + 8 ore lavorate = 16 + 15 minuti di recupero per essere entrato in ritardo di 2 minuti)

Per Tuta
quale allegato?

[pietrol]

In effetti non era perfetta.

Ho provato a correggerla, per favore controlla anche questa

Codice: Seleziona tutto

=(ARROTONDA.DIFETTO(SE(B9<A9;B9+1;B9);1/96)-ARROTONDA.ECCESSO(A9;1/96))-C9


ciao
pietrol

[tutamimetica]

Scusa ma non avevo allegato il file. La fretta fa brutti scherzi. Scusami di nuovo
Ciao tuta

[Flash30005]

Ho provato a correggerla, per favore controlla anche questa

Codice: Seleziona tutto

=(ARROTONDA.DIFETTO(SE(B9<A9;B9+1;B9);1/96)-ARROTONDA.ECCESSO(A9;1/96))-C9


Beh questa sembra Ok anzi è Ok! fa la stessa cosa delle mille parentesi della mia
Volendo mettere anche la pausa che è in C9 con la correzione e usando lo stesso principio avrei

Codice: Seleziona tutto

=(ARROTONDA.DIFETTO(SE(B9<A9;B9+1;B9);1/96)-ARROTONDA.ECCESSO(A9;1/96)-ARROTONDA.ECCESSO(C9;1/96))

e funziona prefettamente

Per Tutamimetica
non ti devi scusare, capita a tutti, solo che non riuscivo a capire se ti riferivi alla formula "allegata" da Pietrol o no
Ho scaricato anche il tuo foglio di calcolo ed è interessante la tabellina ma richiede un po' troppe colonne, però a differenza delle formule in unica cella c'è il fatto che se l'entrata e l'uscita sono a cavallo tra due giorni va in errore
es: entrata ore 22:00 uscita ore 6:00

Bravi ad ambedue e grazie

Ciao

[tutamimetica]

Ciao Flash
effettivamente non funzionava se superava la mezzanotte.
Penso di aver risolto.
ciao Tuta