Funzione per Estrapolare i dati migliori

[papclems]

Ho cercato in giro, ma non ho trovato niente.

sempre collegato al foglio http://www.papclems.com/lega1/NbaStats.htm nello sheet Individual Stats vorrei creare una due funzioni che mi trova i migliori 20 giocatori per media punti, e i migliori 20 per punti massimo segnati.

Entrambi i dati si trovano nello sheet "Stats" il primo (i punti medi) è la colonna D, il secondo il max è la colonna F.



queste due tabelle dovrebbero chiaramente essere aggiornate ad ogni inserimento di una nuova giornata di campionato, ed ordinate in maniera decrescente.

[Anthony47]

Ancora pochi giorni e sarai promosso a Utente Senior...

Allora, sulla colonna D togli gli errori con la formula

Codice: Seleziona tutto

=SE(VAL.ERRORE(MEDIA(INDIRETTO($B2)));"0";MEDIA(INDIRETTO($B2))+RIF.RIGA()/100000)

La parte “+Rif.Riga” evita che ci possano essere risultati alla pari, creando una priorita’ per riga.

A questo punto su Stats ti crei una tabella che abbia:
in prima colonna (qualsiasi sia; io ho usato J) la serie 1,2,3,. . . 20
in colonna 2 e successive , accanto a “1” (nel mio caso ho usato le celle K2:N2) usi le formule:

Codice: Seleziona tutto

=SCARTO($A$1;CONFRONTA(GRANDE(D:D;J2);D:D;0)-1;0)
=GRANDE(D:D;J2)
=SCARTO($A$1;CONFRONTA(GRANDE(F:F;J2);F:F;0)-1;0)
=GRANDE(F:F;J2)

Esse calcolano, rispettivamente:
-il nome e il punteggio dell’ atleta con migliore Media
-il nome e il punteggio dell’ atleta con migliore Max

Poi copi le formule in basso per avere le altre posizioni.

Ciao.

[papclems]

funziona tutto perfettamente.

Come sempre grazie.

E' possibile anche creare una funzione che in una lista di 10 valori, divisi in 3 gruppi, mi prenda i migliori due di ogni gruppo e li sommi?





che divento utente senior è una cosa positiva o negativa :look:

[Anthony47]

Per il nuovo problema, esso implica l' individuazione dei migliori 3,3 di ogni gruppo, che trovi col metodo appena visto.
Poi sugli elenchi ci fai tutte le operazioni che vuoi. Dove e' il problema?

Utente senior e' buono, perche' significa che uno puo' cominciare a dare risposte invece che fare solo domande :-))

Ciao.

[papclems]

no spetta, non ho ben capito

Per esempio nel foglio "squadre" vorrei creare una funzione che per ogni squadre mi prenda i due valori più alti per ogni settore.

(ogni squadra se vedi è divisa in tre settori) quindi vorrei sommare i migliori due del primo settore con imigliori due del secondo con il migliore del 3° settore. Non mi interessano i nomi in questo caso, solo una mera somma dei migliori (migliori due nel caso dei primi due settori).

Ho provato a mettere giù una cosa, (nel foglio la vedi, cmq è questa = =SOMMA(MAX(D5:D12))+(MAX(D13:D20))+(MAX(D21:D24))

Che mi fa la somma del migliore di ogni settore, solo che vorrei per le caselle D5:D12 e D13:D20 i migliori due, non solo il migliore.

[Anthony47]

Ti ho detto di usare il “metodo appena visto”, che non prevede l’ uso di MAX (ovvio che ti restituisce solo 1 valore) ma, per quanto riguarda i punteggi, l’ uso della funzione GRANDE, nella sintassi GRANDE(Range;Posizionamento)
Quindi qualcosa come

Codice: Seleziona tutto

=SOMMA(GRANDE(D5:D12;1)+GRANDE(D5:D12;2)+ etc etc

Il range l’ ho preso dalle formule postate, non so se corrisponde all’ organizzazione dei dati sul foglio Squadre.

Ciao.

[papclems]

Ti ho detto di usare il “metodo appena visto”, che non prevede l’ uso di MAX (ovvio che ti restituisce solo 1 valore) ma, per quanto riguarda i punteggi, l’ uso della funzione GRANDE, nella sintassi GRANDE(Range;Posizionamento)
Quindi qualcosa come

Codice: Seleziona tutto

=SOMMA(GRANDE(D5:D12;1)+GRANDE(D5:D12;2)+ etc etc

Il range l’ ho preso dalle formule postate, non so se corrisponde all’ organizzazione dei dati sul foglio Squadre.

Ciao.

Scusa, lo so che sono un pò duretto di comprendonio, però mi applico

In questa formula praticamente, Grande mi dice che cerca il valore + alto, nelle celle da 5 a 12 della colonna, D poi lo somma al 2° valore più grande sempre nelle stesse celle. (cioè voglio capire se (D5:D12;1 <--- questa cifra qui è quella che indica quale valore uno richiede.

Per ipotesi se io scrivo una formula così SOMMA(GRANDE(D5:D12;4)+(GRANDE(D5:D12;5) lui mi prende solo il 4° e 5° + grandi?

[papclems]

Succede una cosa strana, non so da cosa può dipendere però

http://www.papclems.com/lega1/NbaStatsLega1.xls

io seguendo il tuo suggerimento ho creato questa formula

=SOMMA(Grande(D5:D12;1)+Grande(D5:D12;2)+Grande(D13:D20;1)+Grande(D13:D20;2)+Grande(D21:D24;1)

ma quando mi dà il totale me lo dà inferiore di 1 al totale vero. (nel senso il totale verrebbe 98, la formula mi dà 97 ).


Lo vedi cmq sotto le prime due squadre

[Anthony47]

Bene, direi che l’ applicazione ha prodotto il risultato giusto. Come pure e’ giusta la tua ipotesi sul 4° e 5°.
Non e’ superfluo raccomandare una visita all’ help on line (tab Indice, scrivi Grande e vedi sintassi della funzione ed esempi; e’ una miniera di informazioni).

Per quanto riguarda la discrepanza tra il risultato della formula (97) e a quanto calcolato a occhio (98), e’ solo una "illusione ottica" dovuta agli arrotondamenti all’ intero: basta aggiungere un paio di decimali ai dati di input e al risultato per accorgersi di quale e’ il vero risultato.

Ciao.