Excel Problema formula

[Statix]

Ciao Anthony,
ho un problema con questa formula ,funziona perfettamente,unico problema che mi da i risultati dell'archivio in esame ,all'incontrario,cioè parte dall'alto,a me servirebbe quelli da basso dell'archivio.

Codice: Seleziona tutto

=SE(VAL.ERRORE($A$3-INDICE($A$3:$A$5000;CONFRONTA($P3;$I$3:$I$5000;0)));"";$A$3-INDICE($A$3:$A$5000;CONFRONTA($P3;$I$3:$I$5000;0)))

per avere i risultati esatti devo girare l'archivio con un filtro.
archivio
Range I3:M5000

[Anthony47]

Ohi ohi, non farmi fare il reverse engineering della formula... dimmi che cosa vuoi calcolare e faccio meno fatica; e ti assicuro che prendero' lo spunto dalla tua formula!

Ciao.

[Statix]

Ciao Anthony, la formula mi calcola il ritardo di posizione per ogni colonna dell'archivio
allego 2 foto , nella prima foto la formula calcola un archivio di 4034 estrazioni partendo dall'alto Range I3:M3.
il numero 1 Q3 da come risultato 23,
a me serve calcolare il ritardo partendo dal basso vedi foto 2
il numero 1 dovrebbe darmi in Q3 = 9

[Anthony47]

Prefrisco non ispirarmi alla tua formula, so che mi perdonerai
Prova a mettere in Q3 la formula

Codice: Seleziona tutto

=4036-MAX(RIF.RIGA($3:$4036)*(I$3:I$4036=$P3))

che CONFERMERAI NON CON enter MA con Contr-Maiusc-Enter.
Poi copi Q3 sulle colonne R3:U3, e Q3:U3 in Q4:Q4036

Fai sapere, ciao.

[Statix]

Ciao Anthony,
tutto ok,ho solo dovuto riadattare la formula ai miei archivi,in quanto le estrazioni sono variabili da archivio ad archivio,la ruota Nazionale ha meno archivi, in più ad ogni estrazione ne viene aggiunta 1.
Grazie.

[RPD]

Salve,
sto lavorando su un archivio molto simile a quello su riportato da Statix per cui intervengo in questa discussione per chiedere a chi più esperto di me come posso modificare la formula di Anthony47 in modo che calcoli il ritardo di un numero partendo sì dal basso ma non necessariamente dall'ultima estrazione dell'archivio bensì da una da me specificata in un'altra casella. Ovvero: facendo un esempio sulle immagini riportate da Statix, quale formula dovrebbe esserci in Q3 perché mi dia il ritardo del numero 1 partendo non dall'estrazione 4034 bensì da un'altra da me specificata in C3 (facciamo conto che in C3 io specifichi 4030, il ritardo che dovrebbe risultare sarebbe 5).
Spero di essere stato abbastanza chiaro!
Grazie a tutti

[Anthony47]

Ciao RPD e benvenuto nel forum.
Per quello che chiedi dovrai usare la funzione Indiretto:
-dato il tuo punto di partenza in C3, metti in D3 (o altra cella libera) la formula

Codice: Seleziona tutto

=C3+2

(dove 2 e' il numero di righe vuote prima della prima estrazione)
-poi in Q3 userai

Codice: Seleziona tutto

=$D$3-MAX(RIF.RIGA(INDIRETTO("$3:$"&$D$3))*((INDIRETTO("I3:I"&$D$3))=$P3))

Sempre da confermare con Contr-Maiusc-Enter
Puoi copiare la formula in verticale senza problemi, mentre copiandola in orizzontale dovrai modificare in la stringa "I3:I" in "J3:J", "K3:K", etc.

Ciao, fai sapere.

[RPD]

Grazie Anthony,
la formula modificata sembra fare proprio al caso mio. Solo una cosa: la formula restituisce la prima presenza di un numero salendo dal basso verso l'alto (diciamo così tanto per intenderci); nel caso la formula non ritrovi nessuna presenza restituisce il max ritardo (se l'insieme è da 1 a 4000 restituisce 4000) quando invece preferirei che in quel caso la cella rimanesse vuota. Solitamente la cella vuota io la ottengo con la funzione SE, ma dato che non ho alcuna dimestichezza con le formule in forma di matrice (sono molto efficaci ma ho iniziato a impiegarle da poco, ispirato dai tuoi suggerimenti nei post) gradirei un tuo aiuto!
Grazie

[Anthony47]

Coma hai intuito e' necessario mettere la formula data in un SE:

Codice: Seleziona tutto

=SE(MAX(RIF.RIGA(INDIRETTO("$3:$"&$D$3))*((INDIRETTO("I3:I"&$D$3))=$P3))=0;"";$D$3-MAX(RIF.RIGA(INDIRETTO("$3:$"&$D$3))*((INDIRETTO("I3:I"&$D$3))=$P3)))

Sempre Contr-Maiusc-Enter

Ciao