[Excel] Macro per ordinamento colonne multiple colonna unica

[Dylan666]

Buonasera a tutti, avrei la seguente esigenza: ho un foglio Excel con dei nomi sparsi in varie colonne del foglio (quindi con molte celle vuote tra un nome e l'altro) come in questo screenshot:


Vorrei prendere tutte queste celle non-vuote e metterle, ordinate in maniera crescente, nella colonna A una di seguito all'altra (senza celle vuote in mezzo)
Sapete come fare?

PS: nelle celle alcuni nomi sono presenti più volte, potrebbe esserci un "pippo" in A1 ma anche in E3 ad esempio

[Anthony47]

Non hai chiarito se, in caso di presenze multiple dello stesso nominativo nel riepilogo ne vuoi solo una; assumo quindi che ti servano eventualmente duplicati.
Inoltre sono contrario a soluzioni "non controllabili", ad esempio che alterino i dati di partenza rendendo cosi' impossibile da verificare il risultato.
Questa macro fa qualcosa di simile a quanto chiedi col vincolo che ho appena detto: impostato il range con i dati di partenza (istruzione marcata <<<) aggiunge una nuova colonna A in cui, da A2 verso il basso sono riepilogati i nomi presenti:

Codice: Seleziona tutto

Sub dylan()
Dim myRan As String, myRan2 As Range, Cella As Range
'
myRan = "A1:E50"    '<<< L' intervallo da cui pescare
Range("A1").EntireColumn.Insert
Set myRan2 = Range(myRan).Offset(0, 1)
Cells(1, 1) = "Riepilogo"
For Each Cella In myRan2
    If Len(Cella) > 0 Then
        cnt1 = Application.WorksheetFunction.CountIf(myRan2, "<" & Cella.Value)
        cnt2 = Application.WorksheetFunction.CountIf(Range("A:A"), "=" & Cella.Value)
        Cells(cnt1 + cnt2 + 2, 1) = Cella.Value
    End If
Next Cella
Range("A1").Font.Bold = True
Columns("A:A").EntireColumn.AutoFit
End Sub


Se vuoi puoi successivamente eliminare le colonne di partenza lasciando il solo riepilogo.
Warning: prima di rieseguire la macro andrebbe eliminata la colonna aggiunta.

Fai sapere se ok cosi' o necessiti di logiche alternative.
Ciao

[Dylan666]

Meraviglioso!
I duplicati li devo tenere e la logica della "colonna aggiunta" è perfetta.
Grazie per le soluzioni sempre ottime e velocissime!