Aiuto! Più frequenze in excel

[Grace29]

Ciao a tutti del forum. vorrei chiedervi gentilmente un aiuto.
Vi aspongo il mio problema con excel. Ho una tabella dove all'interno ci sono dei numeri, ad esempio tabella di 5 colonne e un tot. di righe. Devo trovare all'interno di tale intervallo i numeri frequenti. Con la funzione moda =MODA(A1:D10) me ne trova solo uno, io invece ho bisogno che mi mostri più numeri frequenti in quanto ce ne sono minimo 3 o 4 di numeri che si ripetono.
Vi ringrazio se mi darete una mano.

[scossa]

Ciao a tutti del forum. vorrei chiedervi gentilmente un aiuto.
Vi aspongo il mio problema con excel. Ho una tabella dove all'interno ci sono dei numeri, ad esempio tabella di 5 colonne e un tot. di righe. Devo trovare all'interno di tale intervallo i numeri frequenti. Con la funzione moda =MODA(A1:D10) me ne trova solo uno, io invece ho bisogno che mi mostri più numeri frequenti in quanto ce ne sono minimo 3 o 4 di numeri che si ripetono.
Vi ringrazio se mi darete una mano.

i dati in A1:D10

Primo più frequente:

Codice: Seleziona tutto

=MODA($A$1:$D$10)

Secondo più frequente:

Codice: Seleziona tutto

=MODA(SE($A$1:$D$10*($A$1:$D$10<>(MODA($A$1:$D$10)))<>0;$A$1:$D$10))

matriciale da confermare con ctrl+maiusc+invio

Terzo più frequente:

Codice: Seleziona tutto

=MODA(SE(($A$1:$D$10*($A$1:$D$10<>MODA($A$1:$D$10))<>0)*($A$1:$D$10*($A$1:$D$10<>MODA(SE($A$1:$D$10*($A$1:$D$10<>MODA($A$1:$D$10))<>0;$A$1:$D$10)))<>0);$A$1:$D$10))

matriciale da confermare con ctrl+maiusc+invio

Se definisci la zona A1:D10 come Dati si semplifca il tutto in:

Primo più frequente:

Codice: Seleziona tutto

=MODA(Dati)

Secondo più frequente:

Codice: Seleziona tutto

=MODA(SE(Dati*(Dati<>(MODA(Dati)))<>0;Dati))

matriciale da confermare con ctrl+maiusc+invio

Terzo più frequente:

Codice: Seleziona tutto

=MODA(SE((Dati*(Dati<>MODA(Dati))<>0)*(Dati*(Dati<>MODA(SE(Dati*(Dati<>MODA(Dati))<>0;Dati)))<>0);Dati))

matriciale da confermare con ctrl+maiusc+invio

E così via per il quarto.

[Grace29]

Ciao scossa, ti ringrazio per il tuo aiuto ma ho due problemi: il primo è che non sò come inserire la formula del secondo e terzo più frequente in quanto non ho mai usato il seguente comando "matriciale da confermare con ctrl+maiusc+invio", digito i tre tasti ma mi da errore; il secondo problema è che non sò definire la zona come DATI. Ti ringrazio se puoi continuare a spiegarmi ed aiutarmi in questi passaggi.

[wallace&gromit]

ciao grace,
ti rispondo io visto che scossa non è on line.
prima di tutto devi definire il nome "Dati": (in excel2003) vai su Inserisci/nome/definisci scrivi "Dati" in alto e inserisci il tuo range in basso e premi sul tasto aggiungi. In questo modo hai definito un range di celle che puoi selezionare anche dalla barra degli strumenti (tutto a sinistra).

Ora inserisci le formule e premi contemporaneamente ctr, maiusc e enter. Vedrai aggiungersi delle parentesi graffe alla tua formula.

[scossa]

il secondo problema è che non sò definire la zona come DATI. Ti ringrazio se puoi continuare a spiegarmi ed aiutarmi in questi passaggi.

Selezioni le celle A1:D10 e nella finestrella in alto a sinistra (dove appare la scritta A1) digiti Dati e premi invio.

il primo è che non sò come inserire la formula del secondo e terzo più frequente in quanto non ho mai usato il seguente comando "matriciale da confermare con ctrl+maiusc+invio", digito i tre tasti ma mi da errore

Scrivi (o incolli la formula) nella cella che vuoi e, alla fine, anziché premere il solo invio, tenendo schiacciati il tasti ctrl il tasto maiusc premi il tasto invio.

Se hai già la formula nella cella basta premere F2 poi ctrl+maiusc+invio

[Grace29]

Ciao vi ringrazio per l'ulteriore aiuto. Ho risolto uno dei due problemi ma quello relativo al tasto ctrl maiusc e invio non va. Mi da errore. Vorrei inviarvi il foglio di excel per mostrarvi il problema ma non so se si può allegarlo nel post o inviare per e-mail. Io uso excel 2007. Attendo aiuto.. grazie ancora.

[Flash30005]

Puoi utilizzare questa procedura per allegare il file
come server host ti consiglio questo

ciao

[Grace29]

Ciao, ringrazio davvero tutti per la disponibilità. Vi allego il foglio di excel per mostrarvi dove non va.
http://www.filedropper.com/provafrequenze

[CANAPONE]

Ciao, la formule sono scritte bene. Come scriveva Scossa e Wallace&Gromit - un caro saluto- sembra cheti sia chiaro come rendere matriciale la formula.
Sono sul file che hai allegato: clicca due volte su E15 (o vai su E15 e premi il tasto F2 una volta), premendo il tasto ctrl insieme al tasto maiusc (di solito è una freccia che punta verso l'alto sotto il tasto invio) premi invio.
Quindi tenendo i tasti control e maiusc pigiati premi invio: se lo fai correttamente la formula apparirà abbracciata dalle parentesi graffe.
------------------------------------------

Per estendere la moda oltre il terzo numero potresti usare anche queste formule

in D16 (di nuovo)

Codice: Seleziona tutto

=MODA(Dati)

in E16 da copiare e confermare con control+maiusc+invio

Codice: Seleziona tutto

=SE.ERRORE(MODA(SE(CONTA.SE($D$16:D16;Dati);"";Dati));"")

Una volta confermata correttamente basta copiarla verso destra per ottenere tutta la serie decrescente dei numeri.

Se lavori con le statistiche su Excel dovrai spesso lavorare con le formule matrice: non ci sono altri modi


Allego l'esempio

http://www.filedropper.com/provafrequenze_1


Saluti

[CANAPONE]

Ciao di nuovo,

a questo indirizzo ho ottenuto diversi chiarimenti relativi alle formule matrice

http://lucafranchi.wordpress.com/2008/1 ... con-excel/

Se servisse

Saluti

[scossa]

Visto che usi una versione di Excel successiva alla 2003, e se puoi usare colonne di appoggio, la soluzione di Canapone è ottima (come sempre).

La mia è più complicata perché ho voluto evitare l'uso di colonne di appoggio.

[Grace29]

Vi ringrazio tutti! Ora riesco bene, ma ovviamente per complicarsi la vita con le formule ed excel non vi è mai fine.. nell'intervallo dati ora non ho + solo valori numerici ma formule! Vi riporto il file per mostrarvi il mio lavoro, in questo caso la moda con + frequenze non me la calcola.. forse vi è un conflitto tra formule o semplicemente tra i miei neuroni che vanno in tilt!
http://www.filedropper.com/provafrequenze_2

[CANAPONE]

Ciao,

ho capito bene che devi calcolare la MODA fra i numeri in A24:E33? Cioè 70 68 72 69...

Prova in F22

Codice: Seleziona tutto

=MODA(A24:E33)

in G22 da confermare con control+maiusc+invio per renderla matriciale e poi copiarla verso destra.

Codice: Seleziona tutto

=SE.ERRORE(MODA(SE(CONTA.SE(F$22:$F22;$A$24:$E$33);"";$A$24:$E$33));"")

Qui trovi il file:

http://www.filedropper.com/provafrequenze_3


Saluti