inserimento data al volo

[nicola_na78]

Ciao a tutti estiste un modo che mi permette di inserire una data senza dovere usare /?? cioè digitando 110413 diventa 11/04/2013??
grazie

[Flash30005]

Supponendo che le date siano nella colonna A (da A2 a A1000)
Inserisci nel Vba del foglio questo codice

Codice: Seleziona tutto

Private Sub Worksheet_Change(ByVal Target As Range)
Area = "A2:A1000"
If Not Application.Intersect(Target, Range(Area)) Is Nothing Then
Application.EnableEvents = False
MioNum = Format(Target, "000000")
Miadata = CDate(Left(MioNum, 2) & "/" & Mid(MioNum, 3, 2) & "/20" & Right(MioNum, 2))
Target = Miadata
Application.EnableEvents = True
End If
End Sub

Ad ogni digitazione, come da te indicato, ottieni la data richiesta

ciao

[nicola_na78]

grazie flash. funziona
Buona giornata

[wallace&gromit]

comunque, se stai inserendo date dell'anno corrente, il metodo più rapido è scrivere "11/4", basterà a excel per capire 11/04/2013!

[ricky53]

Ciao,
letto quanto scritto da W&G ...

Io aggiungo:
ovviamente la digitazione deve essere costituita da "6" caratteri altrimenti ...

Prova a scrivere "11413" volendo intendere 11 aprile del 2013
oppure
Prova a scrivere "1313" volendo intendere 1 marzo del 2013

Io inserirei un controllo sulla lunghezza della data inserita altrimenti potresti avere ... date diverse da quelle inserite senza accorgetene, come visto prima.


A mio avviso queste scelte di trasformare le data digitate sono ... da evitare perchè possono generare date non rispondenti a quanto l'utente ha scritto.


CONSIGLIO: utilizzando il tastierino numerico l'inserimento delle date è molto facile !

[scossa]

Ciao,

Ciao,
A mio avviso queste scelte di trasformare le data digitate sono ... da evitare perchè possono generare date non rispondenti a quanto l'utente ha scritto.

condivido l'opinione di Ricky, linserimento delle date è sempre rognoso e andrebbe gestito con molta attenzione.

Supponendo che le date siano nella colonna A (da A2 a A1000)
Inserisci nel Vba del foglio questo codice

Codice: Seleziona tutto

Private Sub Worksheet_Change(ByVal Target As Range)
Area = "A2:A1000"
If Not Application.Intersect(Target, Range(Area)) Is Nothing Then
Application.EnableEvents = False
MioNum = Format(Target, "000000")
Miadata = CDate(Left(MioNum, 2) & "/" & Mid(MioNum, 3, 2) & "/20" & Right(MioNum, 2))
Target = Miadata
Application.EnableEvents = True
End If
End Sub

Una semplificazione, al codice sopra, sempre con l'obbligo di digitare la data a 8 cifre e formalmanete valida:

Codice: Seleziona tutto

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Application.Intersect(Target, Me.Range("A2:A1000")) Is Nothing Then
  With Target(1, 1)
    Application.EnableEvents = False
    .Value = CDate(Format(.Value, "00\/00\/0000"))
    Application.EnableEvents = True
  End With
End If
End Sub

[nicola_na78]

ragazzi avete ragione delle volte la macro è instabile, nel senso che se digito 010112 anziche' darmi 01/01/2012 mi restituice 07/09/1927 cosa si puo' fare per risolvere il problema??
grazie

[ricky53]

Ciao,
fare qualcosa significa inserire diversi controlli nel codice ... nel vale la pena?
Nel tuo file ci sono tantissime date da inserire?

Normalmente vige il sacro concetto COSTI / BENEFICI !!!

Io ribadisco il consiglio di utilizzare il tastierino numerico e scrivere le date con il suggerimento di W&G abbandonando l'idea di trasformare le date digitate.

[wallace&gromit]

digito 010112 anziche' darmi 01/01/2012 mi restituice 07/09/1927

il motivo dell'errore è presto spiegato: lo zero iniziale non viene cosiderato, quindi excel considera la data con valore numerico 10112, che è appunto quella del 1927!

una possibile alternativa per velocizzare l'inserimento è scindere le colonne in giorno mese anno e poi compilare la data con la formula =data(anno;mese;giorno). In questo modo crei dei pacchetti con l'anno costante e poi col mese costante per tutti gli inserimenti che hanno stesso mese e stesso anno.

[nicola_na78]

Ragazzi mi sono accorto che la macro nn funziona quando viene immessa una data errata es anzichè scrivere 010113 scrivo 01011, la macro si impalla e non funziona più. Se chiudo e riapro excel tutto funziona...
si puo' modifirare la macro facendo in modo che ogni volta che termina l'istruzione questa svuota pure la cache di excel??? come se in pratica venisse chiuso e poi riaperto....
grazie

[scossa]

Ragazzi mi sono accorto che la macro nn funziona quando viene immessa una data errata es anzichè scrivere 010113 scrivo 01011, la macro si impalla e non funziona più. Se chiudo e riapro excel tutto funziona...
si puo' modifirare la macro facendo in modo che ogni volta che termina l'istruzione questa svuota pure la cache di excel??? come se in pratica venisse chiuso e poi riaperto....
grazie

E' dall'inizio che ti diciamo che la macro funziona solo se digiti 8 cifre e se queste sono formalmente una data!

[Anthony47]

Da quello che descrivi credo che stia parlando di quando ottieni un errore all' interno della macro e la termini; in questo modo gli "Eventi" rimangono disabilitati.
Con tutte le approssimazioni che la tua richiesta comporta, in particolare riguardo errati risultati quando violi la regola dei caratteri da inserire nella cella, prova a modificare la macro di Flash come segue:

Codice: Seleziona tutto

Private Sub Worksheet_Change(ByVal Target As Range)
Area = "A2:A1000"
If Not Application.Intersect(Target, Range(Area)) Is Nothing Then
Application.EnableEvents = False
MioNum = Format(Target, "000000")
MiaData = CVErr(xlErrNA)
On Error Resume Next
MiaData = CDate(Left(MioNum, 2) & "/" & Mid(MioNum, 3, 2) & "/20" & Right(MioNum, 2))
Target = MiaData
Application.EnableEvents = True
End If
End Sub


In caso di errori dove il risultato non puo' essere trasformato in una data viene inserito in cella l' errore #N/D.
Come ulteriore controllo per ridurre le occasioni di errore si potrebbe controllare se la data e' compresa in un intervallo di min e max, se puoi definire delle regole in tal senso.

Ciao

[nicola_na78]

Grazie Antoni47 questa modifica è perfetta, ora tutto funziona come volevo io....
grazie a tutti

[scossa]

Ragazzi mi sono accorto che la macro nn funziona quando viene immessa una data errata es anzichè scrivere 010113 scrivo 01011, la macro si impalla e non funziona più. Se chiudo e riapro excel tutto funziona...
si puo' modifirare la macro facendo in modo che ogni volta che termina l'istruzione questa svuota pure la cache di excel??? come se in pratica venisse chiuso e poi riaperto....
grazie

Oltre la soluzione di Anthony, modifica così il codice che avevo proposto:

Codice: Seleziona tutto

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Application.Intersect(Target, Me.Range("A2:A1000")) Is Nothing Then
  With Target(1, 1)
    If IsDate((Format(.Value, "00\/00\/0000"))) Then
      Application.EnableEvents = False
      .Value = CDate(Format(.Value, "00\/00\/0000"))
      Application.EnableEvents = True
    End If
  End With
End If
End Sub

[ricky53]

Ciao,
il mio pensiero sulla questione l'ho espresso più volte ma incuriosito dalle due soluzioni proposte ho voluto fare alcune prove, ed ecco il risultato.

La macro di Flash con la modifica di Anthony: non mi ha dato errori

La macro di Scossa va in errore se una volta inserita una data (viene correttamente trasformata) vado in modifica della data presente ed inserisco una data diversa.
Se inserisco la stessa data non ho errori.

L'errore che ottengo è "run-time 6 Overflow" e si ha sull'istruzione

Codice: Seleziona tutto

If IsDate((Format(.Value, "00\/00\/0000"))) Then

[ricky53]

Ciao,
altre prove.

Con la soluzione di Flash-Anthony: se non si inseriscono sei caratteri alcune date vengono alterate.

Ad esempio scrivendo "20113" intendendo 20 gennaio 2013 ma essendo un valore non univoco ... quindi si ottiene "02/01/2013"

Andrebbe inserito un opportuno controllo sul dato inserito.

[scossa]

La macro di Scossa va in errore se una volta inserita una data (viene correttamente trasformata) vado in modifica della data presente ed inserisco una data diversa.
Se inserisco la stessa data non ho errori.

L'errore che ottengo è "run-time 6 Overflow" e si ha sull'istruzione

Codice: Seleziona tutto

If IsDate((Format(.Value, "00\/00\/0000"))) Then

Hai ragione, non ho tenuto conto che la cella viene formattata come data; ma la soluzione è semplice, basta usare la proprietà .Value2 anziché .Value:

Codice: Seleziona tutto

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Application.Intersect(Target, Me.Range("A2:A1000")) Is Nothing Then
  With Target(1, 1)
    If IsDate((Format(.Value2, "00\/00\/0000"))) Then
      Application.EnableEvents = False
      .Value = CDate(Format(.Value2, "00\/00\/0000"))
      Application.EnableEvents = True
    End If
  End With
End If
End Sub

[ricky53]

Ciao Scossa,
Ottimo.


Mi permetto di aggiungere un controllo sul corretto formato da inserire nelle celle:

Codice: Seleziona tutto

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Application.Intersect(Target, Me.Range("A2:A1000")) Is Nothing Then
        With Target(1, 1)
            If IsDate((Format(.Value2, "00\/00\/0000"))) Then
                Application.EnableEvents = False
                .Value = CDate(Format(.Value2, "00\/00\/0000"))
                Application.EnableEvents = True
            Else
                MsgBox "Il valore  '" & Target & "'  inserito in  '" & Target.Address(0, 0) & "'  non è in formato DATA." & vbCrLf & "Il formato corretto è:  'ggmmaaaa'"
            End If
        End With
    End If
End Sub


[Anthony47]

Con la soluzione di Flash-Anthony: se non si inseriscono sei caratteri alcune date vengono alterate.
Ad esempio scrivendo "20113" intendendo 20 gennaio 2013 ma essendo un valore non univoco ... quindi si ottiene "02/01/2013"

Il problema e' comune a tutte le proposet pubblicate, ed e' dall' inzio che diciamo che il rischio c' e'; per compensarlo ci vorrebbe un sensore neurale.

Ciao!

[ricky53]

Ciao,
infatti il mio intervento era per evidenziare di applicare le condizioni in modo rigoroso ed allora si ha un buon margine di sicurezza dei dati inseriti.