Formula primo lunedi del mese precedente

[Sasyjoe]

Buongiorno.
In cella A1 ho la data 1/12/14 (PRIMO LUNEDI DEL MESE DI DICEMBRE)

In cella B1 VORREI LA DATA DEL PRIMO LUNEDI DEL MESE ANTECEDENTE AL MESE DELLA DATA IN A1.

Nel caso specifico vorrei in B1 la formula che mi restituisce 3/11/14 cioè il primo lunedi del mese di novembre.

Grazie

[Anthony47]

Prova con

Codice: Seleziona tutto

=FINE.MESE(A1;-2)+1+7-GIORNO.SETTIMANA(FINE.MESE(A1;-2)+1;3)


Ciao

[Sasyjoe]

L'ho testata. Purtroppo è fallabile nel seguente caso:

se in A1 scrivo 6/10/14 mi restituisci in B1 il secondo lunedi di settembre e cioè 8/9/14.

[ricky53]

Ciao,
una mia veloce complicazione alla formula di Anthony che risolve la problematica che hai rilevato

Codice: Seleziona tutto

=FINE.MESE(A2;-2)+1 + SE(GIORNO.SETTIMANA(FINE.MESE(A2;-2)+1; 3)>0; 7- GIORNO.SETTIMANA(FINE.MESE(A2;-2)+1; 3); 0)

[Sasyjoe]

Mi da riferimento circolare!

Ciao

[scossa]

Versione "lunga":

Codice: Seleziona tutto

=FINE.MESE(A1;-2)+1+(8-GIORNO.SETTIMANA(FINE.MESE(A1;-2)+1;2))*(GIORNO.SETTIMANA(FINE.MESE(A1;-2)+1;2)>1)

[ricky53]

Ciao,
strano. In quale cella hai copiato la formula? In "B1" ?

Io l'avevo provata sulla cella "A2", nella formula che ti ho inviato prova a cambiare "A2" con "A1"

[CANAPONE]

Ciao a tutti,

senza alcuna vergogna condivido anche questo impresentabile MIN matriciale:

Codice: Seleziona tutto

=MIN(SE(GIORNO.SETTIMANA(DATA(ANNO(A1);MESE(A1)-1;1)+RIF.RIGA($1:$7)-1)=2;DATA(ANNO(A1);MESE(A1)-1;1)+RIF.RIGA($1:$7)-1))

Formula da confermare con control+maiusc+invio.

Saluti

[Anthony47]

Beh, per confondere il buon Sasyjoe pubblico anche questa:

Codice: Seleziona tutto

=FINE.MESE(A1;-2)+1+RESTO(7-GIORNO.SETTIMANA(FINE.MESE(A1;-2)+1;3);7)

Ciao!

[Sasyjoe]

Putroppo solo adesso ho letto.

comunque ho abbozzato questa che sembra funzionare:

=SE(MESE(A1-35)<>SE(MESE(A1)=1;12;MESE(A1)-1);A1-28;A1-35)

Non è "bella" come la vostra formula ma sembra funzionare.

Grazie a tutti, ciaooo

[ricky53]

Ciao,
la tua formula non fornisce il primo lunedì del mese precedente ma ti fornisce il primo giorno della settimana del mese precedente che sia uguale al giorno della settimana della data che hai inserito in "A1".

Prova a scrivere in "A1" il giorno 03-12-2014 che è "mercoledì" cosa ottieni in "B1" ?
Avrai 05-11-2014 che è mercoledì.
Con le altre soluzioni proposte, invece, avresti avuto 03-11-2014 che è lunedì.

[Sasyjoe]

Hai ragione!

[ricky53]

Ciao,
hai un'ampia scelta di soluzioni da adottare, tutte molto valide.
Aggiornaci.

[CANAPONE]

Ciao a tutti,

stesso ragionamento, ma usando AGGREGA disponibile con Excel 2010 e versioni successive

Codice: Seleziona tutto

=AGGREGA(15;6;DATA(ANNO(A1);MESE(A1)-1;1)+RIF.RIGA($1:$7)-1/(GIORNO.SETTIMANA(DATA(ANNO(A1);MESE(A1)-1;1)+RIF.RIGA($1:$7)-1)=2);1)

Basta copiare la formula, non richiede lo stato matriciale.

Saluti