evidenziare in rosso riga se cambia valore cella

[piipo4]

Salve a tutti sono nuovo del forum, ho un foglio excel con una serie di dati, sto cercando di far evidenziare un range di celle sulla stessa riga, se nella colonna J viene immessa un valore(una data nel mio caso) il codice che inserito è questo

Private Sub Worksheet_Change(ByVal Target As Range)

Dim x As Integer

x = ActiveCell.Row
If Target.Address = "$J$" & x Then
x = x - 1
If Range("J" & x) <> "" Then
Range("A" & x & ":" & "M" & x).Select
With Selection.Font
.Color = -16777024
.TintAndShade = 0
End With
Selection.Font.Bold = True
Range("j" & x).Select
End If
End If



la cosa strana è che mi evidenzia il range solo se cancello il dato da una delle celle della colonna "J", quano inserisco la data non succede nulla... qualcuno può aiutarmi?

Grazie a tutti

[Anthony47]

Ciao piipo4, benvenuto nel forum.
Per ragionare correttamente devi usare "Target" e non "ActiveCell"; credo che questa sia una versione funzionante del tuo codice (che sia la logica giusta non lo so):

Codice: Seleziona tutto

Private Sub Worksheet_Change(ByVal Target As Range)
'
If Target.Column = 10 Then
    If Target.Value <> "" Then
        With Target.Offset(0, -9).Resize(1, 13).Font
            .Color = -16777024
            .TintAndShade = 0
        End With
    End If
End If
End Sub

Ciao

[ricky53]

Ciao,
prova con questa modifica al tuo cidice

Codice: Seleziona tutto

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Intervallo As Range, X As Integer
   
    Set Intervallo = Range("J2:J1000") ' <<===== adatta l'intervallo alla tua situazione effettiva
    If Not Intersect(Target, Intervallo) Is Nothing Then
            X = Target.Row
            If Target.Value <> "" Then
            With Range("A" & X & ":" & "M" & X).Font
                .Color = -16777024
                .TintAndShade = 0
                .Bold = True
            End With
        Else
            With Range("A" & X & ":" & "M" & X).Font
                .FontStyle = "Normale"
                .ColorIndex = xlAutomatic
            End With
        End If
    End If
End Sub


Non ho inserito il controllo che il valore inserito nella cella "J.." sia una data ma solo che la cella non sia vuota come avevi scritto tu ma sarebbe il caso di fare qualche controllo, vedi tu.

Inoltre ActiveCell.Row ti restituisce la riga successiva, per questo motivo utilizzi l'istruzione x = x -1 ???
Non va bene ActiveCell !!!



OPS ... ho scritto senza controllare se c'erano altre risposte ... SORRY !!!

[piipo4]

Non ho inserito il controllo che il valore inserito nella cella "J.." sia una data ma solo che la cella non sia vuota come avevi scritto tu ma sarebbe il caso di fare qualche controllo, vedi tu.

Inoltre ActiveCell.Row ti restituisce la riga successiva, per questo motivo utilizzi l'istruzione x = x -1 ???
Non va bene ActiveCell !!!

Grandissimo funzione perfettamente, grazie, si in effetti avevo messo l'istruzione x=x-1, perchè inserendo la data e dando invio, "x" prendeva il valore della cella più in basso. il controllo data non è fondamentale tanto li ho bisogno di inserire per forza un data.
Grazie ancora.

[ricky53]

Ciao,
bene.
Grazie per il riscontro.
Buon proseguimento e ... alla prossima.