[Excel] macro conta simili e accoda

[macio66]

Ciao
Ho un quesito da porvi.
Mi servirebbe creare una macro che, da uno scarico effettuato giornalmente da un file chiamato "Master", prenda i dati ( testo) della prima colonna chiamata "Materiale" (la lunghezza della prima colonna non è uguale x ogni scarico).
esempio:
Materiale
a
b
c
a
a
d
e
b
a

e me li vada ad accodare su un altro file chiamato "Scarico" già esistente, facendo la somma del testo uguale ed aggiungendo la data dello scarico.
esempio:
Materiale Somma Data
a 4 17/03/2016
b 2 17/03/2016
c 1 17/03/2016
d 1 17/03/2016
e 1 17/03/2016

Sperando di essere stato chiaro, resto in attesa di vostri suggerimenti.
Grazie

[Anthony47]

Prova con questa macro, che devi inserire in un modulo standard del file Scarico:

Codice: Seleziona tutto

Sub Riporta()   
'Vedi http://www.pc-facile.com/forum/viewtopic.php?f=26&t=106592
Dim From As Worksheet, myNext As Long, FMax As Long, myCheck As Range
Dim myMatch, I As Long
'
Set From = Workbooks("MASTER.xlsx").Sheets("Foglio1")     '<<< File e Foglio da cui prelevare
'
ThisWorkbook.Activate
Sheets("Foglio1").Select                                  '<<< Il foglio su cui importare
myNext = Cells(Rows.Count, 1).End(xlUp).Row + 1
FMax = From.Cells(Rows.Count, 1).End(xlUp).Row
Set myCheck = Cells(myNext, 1).Resize(FMax + 10, 1)
For I = 2 To FMax
    myMatch = Application.Match(From.Cells(I, 1).Value, myCheck, 0)
    If IsError(myMatch) Then
        Cells(Rows.Count, 1).End(xlUp).Offset(1, 0) = From.Cells(I, 1).Value
        Cells(Rows.Count, 1).End(xlUp).Offset(0, 1) = 1
        Cells(Rows.Count, 1).End(xlUp).Offset(0, 2) = Int(Now)
    Else
        myCheck.Cells(myMatch, 2).Value = myCheck.Cells(myMatch, 2).Value + 1
    End If
Next I
End Sub


Le righe marcate <<< vanno compilate come da commento.

Il file da cui prelevare deve essere gia' aperto.

Poi mandi in esecuzione la macro "Riporta", eventualmente associandola a un pulsante.

Ciao

[macio66]

Ciao Anthony
Ho provato la macro e funziona perfettamente.
Come sempre non posso fare altro che ringraziarti/vi.