Classifica somma duplicati

[Statix]

Ciao a tutti,
ho un problema nel fare una classifica,
ho provato a cercare nel sito ma non trovo quello che cerco,
mi servirebbe una macro
che mi somma i duplicati e dopo stila una classifica senza duplicati,
allego una foto,
i nomi sono in colonna C e i punti in colonna W

[cromagno]

Ciao,
qualche domanda...

Perchè vuoi una macro e non delle semplici formule (visto che si può fare)?
Sai fare qualcosa in VBA e quindi vuoi qualche consiglio o vuoi il codice "bello e pronto"?
Inoltre, sarebbe meglio se allegassi anche un file d'esempio dove poter lavorare (quello da cui hai preso l'immagine), in modo da evitare a chi volesse aiutarti di doverselo creare da zero.

Ciao
Tore

[Anthony47]

Aggiungo a quanto detto da Cromagno /Tore (vedi sopra) che puoi ottenere quel che chiedi con una semplice tabella pivot; al massimo ti tocca fare in modo che la colonna dei nominativi e quella dei punti siano contigue (per evitare di dover dare una intestazione a tutte le colonne intermedie).

Ciao

[cromagno]

...comunque, rimanendo sempre valido quanto detto prima ma non ho sonno....

Uno dei modi, lato formule, potrebbe essere con due colonne di appoggio (AC e AD) che poi nasconderai:


Nella cella AC3 (da copiare poi in basso):
=SE(CONTA.SE($C$3:$C3;C3)>1;"";C3)

nella cella AD3 (da copiare poi in basso):
=SE(AC3="";"";SOMMA.SE($C$3:$C$15;AC3;$W$3:$W$15))

nella cella AA3 (da copiare poi nella cella AB3 ed in basso):
=SE.ERRORE(INDICE(AC$3:AC$15;CONFRONTA(AGGREGA(14;6;$AD$3:$AD$15+RIF.RIGA($AD$3:$AD$15)/1000;RIF.RIGA(A1));INDICE($AD$3:$AD$15+RIF.RIGA($AD$3:$AD$15)/1000;;);0));"")

Ti allego il file....
https://www.dropbox.com/s/xoa492wudovehjx/Class%20-%20doppioni.xlsx?dl=0

[Anthony47]

Ciao Tore, anche tu fai le ore piccole, eh...

[cromagno]

eh già...
le formule ci sono...ora tocca a te col VBA

Ciao Anthony

[Anthony47]

No no, che vba; per me la pivot e' la piu' semplice (da' l'elenco, da' i punteggi, mette in ordine), e poi ci sono le tue formule.
Vedrai che Statix dira' "Troppa grazia, troppo buoni"

Buonanotte!

[paolodig]

Ciao a tutti, quanto sopra è il mio risultato con un'unica colonna di appoggio AC:

AC3=SE(MATR.SOMMA.PRODOTTO(--($C$3:$C$15=C3);$W$3:$W$15;--(CONTA.SE(C3:C15;$C$3:$C$15)=1))=0;"";MATR.SOMMA.PRODOTTO(--($C$3:$C$15=C3);$W$3:$W$15;--(CONTA.SE(C3:C15;$C$3:$C$15)=1)))

Di conseguenza:
AA3=SE.ERRORE(INDICE($C$3:$C$15;CONFRONTA(GRANDE($AC$3:$AC$15;RIF.RIGA(A1));$AC$3:$AC$15;0));"")

AB3=SOMMA.SE($C$3:$C$15;AA3;$W$3:$W$15) , con formato numero [0;-0;""]


Ho provato a non usare colonne di appoggio, ma il massimo che riesco ad ottenere è quanto in figura qui sotto, che pero' viene compilata tutta in automatico. Nell'ordine:

AA3=SE.ERRORE(INDICE($C$3:$C$15;CONFRONTA(0;INDICE(CONTA.SE(AA$2:AA2;$C$3:$C$15););0));"")

AB3=SOMMA.SE($C$3:$C$15;AA3;$W$3:$W$15) , con formato numero [0;-0;""]

Z3=SE(AB3=0;"";RANGO(AB3;AB$3:AB$15;0)&"°") , con formato numero [0;-0;""]



un saluto

[Anthony47]

Grazie anche per il tuo contributo, ora Statix ha molte proposte su cui sbizzarrirsi...

[Statix]

Ciao a tutti,
ho usato le formule di cromagno ,
volevo ringraziare
cromagno paolodg ed Anthony47
grazie