REPORT DATI DA TABELLA EXCEL.

[ILCUOCO]

SALVE A TUTTI. PROBLEMINO CON EXCEL SPERO POSSIATE AIUTARMI.

HO UNA TABELLA CHE SOSTANZIALMENTE CONSISTE IN UN ELENCO

ES:

NOME DATA PRES/ASS (PRES ASS SONO REGOLAMENTATE DA UNA CASELLA A TENDINA CONTENETE I DUE VALORI)
MARCO 01/01/2018 PRESENTE
GIANNI 01/01/2018 ASSENTE
PINO 01/01/2018 ASSENTE

HO GIA' IMPOSTATO IL TUTTO IN MODO CHE I DATI CHE MI SERVONO PRESENTI NELLA TABELLA, VENGANO AUTOMATICAMENTE RICOPIATI SU ALTRO FOGLIO EXCEL ALL'INTERNO DI UNA SORTA DI CEDOLINO (UNO PER CIASCUNO SOGGETTO IN ELENCO) IN DOPPIA COPIA.

MARCO MARCO
01/01/2018 01/01/2018
PRESENTE PRESENTE

GIANNI GIANNI
01/01/2018 01/01/2018
ASSENTE ASSENTE

PINO PINO
01/01/2018 01/01/2018
ASSENTE ASSENTE

E FINO A QUI... TUTTO BENE
IL PROBLEMA E' CHE A ME SERVIREBBE AVERE IL CEDOLINO SOLO ED ESCLUSIVAMENTE DI MARCO IN CUI IL VALORE DELLA CASELLA "PRES/ASS" E' UGUALE A "PRESENTE". HO PROVATO CON I FILTRI MA ESSENDO I CEDOLINI TABELLINE INDIPENDENTI, NON Và IL FILTRAGGIO.
FACCIO PRESENTE CHE IL REPORT NEL CEDOLINO DEI SOLI "PRESENTE" PUò AVVENIRE ANCHE IN UN ALTRO FOGLIO, ANDANDO A SCREMARE I REPORT COMPLESSIVI
IN SOSTANZA STANDO ALLA TABELLA INIZIALE, IL RISULTATO FINALE DOVREBBE ESSERE UN FOGLIO EXCEL DELLO STESSO FILE, IN CUI IL REPORT SIA IL SEGUENTE

ES:
MARCO MARCO
01/01/2018 01/01/2018
PRESENTE PRESENTE

SCUSATE LA LUNGAGGINE MA CREDO DI ESSERE STATO MOLTO PIU' CHIARO CON L'ESEMPIO PRATICO DI QUANTO LO SAREI STATO SPIEGANDO.

GRAZIE A TUTTI IN ANTICIPO.

[wallace&gromit]

Ancora più chiaro sarebbe un file d'esempio.

P.F. non usare il "Caps Lock" quando scrivi, il testo risulta sgradevole (equivale ad urlare nei colloqui a voce)

[Anthony47]

HO GIA' IMPOSTATO IL TUTTO IN MODO CHE I DATI CHE MI SERVONO PRESENTI NELLA TABELLA, VENGANO AUTOMATICAMENTE RICOPIATI SU ALTRO FOGLIO EXCEL ALL'INTERNO DI UNA SORTA DI CEDOLINO (UNO PER CIASCUNO SOGGETTO IN ELENCO) IN DOPPIA COPIA.

Devi intervenire in questa fase, condizionando la copia al fatto che il contenuto di colonna C sia "PRESENTE", saltando cioe' la copia di quei dato dove invece risulta un valore diverso.

E se non risolvi con questo spunto allora allega un file dimostrativo.
Per le istruzioni su come allegare un file:
viewtopic.php?f=26&t=103893&p=605487#p605487

Per favore non scrivere frasi in maiuscolo.

Ciao

[ILCUOCO]

Ecco l'esempio. https://we.tl/GOnLApvkHe
Grazie mille Antony, avevo pensato di allegare file ma non sapevo come fare

[Anthony47]

Mah... non ti dico il mio primo pensiero a guardare la struttura dei dati...

Allora...
1) Tasto destro sul tab col nome Foglio1; scegli Visualizza codice per aprire l'editor delle macro
2) Copia questo codice e incollalo nel frame vuoto di destra della finestra che si e' aperta

Codice: Seleziona tutto

Private Sub Worksheet_Change(ByVal Target As Range)
Dim myArea As String
'
myArea = "B3:D8"            '<<< L'area con gli elenchi
'
If Not Application.Intersect(Target, Range(myArea)) Is Nothing Then
    Application.EnableEvents = False
    Call Presenti
    Application.EnableEvents = True
End If
End Sub


3) Menu /Inserisci /Modulo
4) Copia questo altro codice e incollalo nella nuova finestra

Codice: Seleziona tutto

Sub Presenti()
Dim Tab0 As Range, List0 As Range, Inter As Integer, J As Integer
'
Set List0 = Range("B3")         '<<< Dove comincia la lista dei presenti/assenti
Set Tab0 = Range("L30")         '<<< Dove comincera' la tabella creata
Inter = 5                       '<<< La distanza in colonne tra le due colonne generate

Tab0.Offset(-1, 0).Resize(100, Inter + 3).Clear
Do
ocol = (J Mod 2) * 4
    If List0.Offset(I, 0) <> "" Then
        If List0.Offset(I, 2) = "presente" Then
            Tab0.Offset(Int(J / 2) * Inter, ocol + 0) = List0.Offset(I, 0)
            Tab0.Offset(Int(J / 2) * Inter, ocol + 1) = List0.Offset(I, 1)
            Tab0.Offset(Int(J / 2) * Inter, ocol + 1).NumberFormat = "[$-410]dd-mmm-yy;@"
            Tab0.Offset(Int(J / 2) * Inter, ocol + 2) = List0.Offset(I, 2)
            o3Box Tab0.Offset(Int(J / 2) * Inter, ocol + 0)
            J = J + 1
        End If
    Else
        Exit Do
    End If
    I = I + 1
Loop
End Sub

Sub o3Box(ByRef myRan As Range)
Dim J As Integer, I As Integer
For J = 0 To 2
    With myRan.Offset(-1, J).Resize(3, 1)
        .Borders(xlDiagonalDown).LineStyle = xlNone
        .Borders(xlDiagonalUp).LineStyle = xlNone
        For I = 7 To 10
            With .Borders(I)
                .LineStyle = xlContinuous
                .ColorIndex = 0
                .TintAndShade = 0
                .Weight = xlThin
            End With
        Next I
    End With
Next J
End Sub


Le istruzioni marcate <<< sono da personalizzare per dichiarare:
a)quale e' l'area della tabella con Nomi /Date / Presenze su Foglio1
b)dove comincia la colonna con Presente /Assente
c)dove andranno posizionati i risultati che si vogliono ottenere; io ho usato L30 per confrontare quanto ottenuto con quanto richiesto
d)la distanza in colonne Excel tra le due colonne di dati generati

Quando tutto e' pronto vai su Foglio1; modifica la tabella e quarda l'effetto che fa.

NB: la procedura di volta in volta rigenera tutta la tabella di uscita, cancellando SENZA PREAVVISO un intervallo di 100 righe e N colonne (quanto dichiarato al punto "d)" piu' 6 colonne) a partire dall'origine dichiarata al punto "c)".

Ciao

[ILCUOCO]

Grazie mille. Ci provo e ti faccio sapere.