contare tutti i turni singolo tec

[raimea]

ciao
dovrebbe essere l ultimo sforzo su questo file !

tramite una macro , vorrei riuscire a contare tutti i turni
di un singolo tecnico e riportarli in foglio >>> "tec_statis "

il tecnico da ricercare lo scrivo in cella D6
la data da cui partire a contare in D3

il file e composto da molti fogli
quindi il foglio dove cercare e' scritto in D4

in fgl "tec_statis " i turni da verificare e contare sono 10
piu il numero di settimane che compongono il calendario attuale

il risultato lo vorrei in col G da riga 7

1_il primo controllo da fare e' sapere di quante settimane
e composto il calendario
x fare questo basta contare la lettera L (i lunedi)
di riga 1 di ogni foglio.

poi:

2_ quanti turni B solo dal lun_ven
3_ quanti turni B solo di sabato
4_ quanti turni B solo di domenica

5_ quanti turni 1 solo dal lun_ven[url][/url]
6_ quanti turni 1 solo di sabato

7_ quanti turni 2 solo di lun_ven
8_ quanti turni 2 solo di sabato

9_ quanti turni LL solo dal lun_ven
10_ quanti turni X solo dal lun_ven
11_ quanti turni RI solo dal lun_ven




vi allego un file x test

https://www.dropbox.com/s/0ytwfpnylsip6hu/singolo_tec_statist_2.rar?dl=0


grazie

[Anthony47]

Il quesito si puo' risolvere anche tramite formule, "giocando" con Indice, Confronta e Indiretto.
Ad esempio, in G8

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(INDIRETTO("'"&$D$4&"'!I2:NZ2");2)<6);--(INDICE(INDIRETTO("'"&$D$4&"'!I1:NZ100");CONFRONTA($D$6;INDIRETTO("'"&$D$4&"'!D1:D100");0);0)=""&E8))


Poi la copi verso il basso
Viene usato INDIRETTO per far dipendere la formula dal nome foglio scritto in D4
CONFRONTA invece determina su quale riga si trova il nominativo prescelto, e viene usato per scegliere una riga nella matrice indicata in INDICE.

La parte "<6" indica Lu-Ve; quindi laddove vuoi invece solo Sab modificherai in "=6", e dove vuoi la Dom modificherai in "=7"

Fai sapere...

[Anthony47]

Noto che c'e' anche una data di partenza di cui tenere conto, pertanto bisogna introdurre un terzo campo in Matr.Somma.Prodotto:

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(INDIRETTO("'"&$D$4&"'!I2:NZ2");2)<6);--(INDIRETTO("'"&$D$4&"'!I2:NZ2")>=$D$3);--(INDICE(INDIRETTO("'"&$D$4&"'!I1:NZ100");CONFRONTA($D$6;INDIRETTO("'"&$D$4&"'!D1:D100");0);0)=""&E8))


Valgono le stesse considerazioni fatte sopra su come modificare la formula per Sab e Dom

Ciao

[raimea]

ciao
ho riportato come descritto la formula nel fgl tec_statist
nella cornice rossa di SX ci sono i calcoli fatti a mano

il calcolo dei turni B L_V mi viene errato
da 27 dovrebbe esere 35

anche turni LL L_V mi da 1 dovrebbe essere 2

ho provato ad adattare la formula
per contare i lunedi (punto 1) ma mi da errore
questo come l ho scritta

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(INDIRETTO("'"&$D$4&"'!I1:NZ1");2)=1);--(INDIRETTO("'"&$D$4&"'!I1:NZ1")>=$D$3);--(INDICE(INDIRETTO("'"&$D$4&"'!I1:NZ100");CONFRONTA($D$6;INDIRETTO("'"&$D$4&"'!D1:D100");0);0)=""&E7))

so che potrei farlo con:

Codice: Seleziona tutto

=CONTA.SE('tec bassi'!I1:NZ1;"L")

ma non terrebbe conto di quale foglio analizzare,andrebbe modif manualmente ogni volta





ciao

[Anthony47]

Secondo me i calcoli che ritieni esatti partono dalla prima data presente nel foglio, cioe' ignorano la data di partenza impostata in D3. Se D3 e' da ignorare allora va bene la formula che ti avevo proposto nella prima risposta.
Quanto al calcolo in riga 7 (e probabilmente in riga 19) l'avevo proprio dimenticato; potresti usare:
in G7

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(INDIRETTO("'"&$D$4&"'!I2:NZ2");2)=1);--(INDIRETTO("'"&$D$4&"'!I2:NZ2")>=$D$3))

e in G19 (tramite il "noto" adattamento del Sabato=6)

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(INDIRETTO("'"&$D$4&"'!I2:NZ2");2)=6);--(INDIRETTO("'"&$D$4&"'!I2:NZ2")>=$D$3))


Ciao

[raimea]

ciao
e' tutto ok

sono correte gia' le formule del 1Mo Post !!

errore MIO
non avevo considerato che il tot 35 B L_V
l' ho ottenuto partendo dal gg 20-4
mentre nel file c'e la data 1-5 !!

Pardon

e Grazie

[raimea]

ciao

vorrei far contare anche le reperibilita' in G15
del dipendente selezionato.

vorrei contare quante volte c'e la scritta -reperibile-

ho riportato la stessa formula
che funziona correttamente per gli altri casi
ma no ho avuto successo.
per questa scritta non mi interessa il controllo del giorno LU_DO
vorrei solo contare le scritte.

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--(GIORNO.SETTIMANA(INDIRETTO("'"&$D$4&"'!I2:NZ2");2)<6);--(INDIRETTO("'"&$D$4&"'!I2:NZ2")>=$D$3);--(INDICE(INDIRETTO("'"&$D$4&"'!I1:NZ300");CONFRONTA($D$6;INDIRETTO("'"&$D$4&"'!D1:D300");0);0)=""&E15))

provata io :

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO(--(INDIRETTO("'"&$D$4&"'!I2:NZ2")>=$D$3);--(INDICE(INDIRETTO("'"&$D$4&"'!I1:NZ300");CONFRONTA($D$6;INDIRETTO("'"&$D$4&"'!D1:D300");0);0)=""&E15))

mi vengono dubbi perche' PURTROPPO
la scritta - reperibile - e' stata messa
in unione celle e la devo lasciare cosi

vi allego il file

https://www.dropbox.com/s/w3xjh59ses5v34u/conta_reperibile.rar?dl=0

grazie

[Anthony47]

Potresti provare con:

Codice: Seleziona tutto

=SOMMA(--(SE((INDIRETTO("'"&D4&"'!I2:DB2")>=D3)*(INDIRETTO("'"&D4&"'!I2:DB2")<=tec_statist!G3);INDICE(INDIRETTO("'"&D4&"'!I1:DB130");1+CONFRONTA(D6;INDIRETTO("'"&D4&"'!D:D");0);0);"")="Reperibile"))

Matriciale, cioe' Contr-Maiusc-Enter

Come intervalli ho usato quelli compilati nel file allegato; eventualmente devi espandere per adattare

Ciao

[raimea]

ciao

ottima ... (come sempre )

tutto ok

grazie mille

[Anthony47]

Si, ma prima provala

[raimea]

provata ... provata...

ero al pc
come visto la tua risposta
(ero in trepida attesa... )

ripeto : tutto ok

ciao