macro excel esecuzione lenta

[libraio]

Windows7 + Excel2003

Ciao a tutti,
avendo l'esigenza di eliminare in un foglio l'intera riga quando nella cella in colonna E il dato è "0,00)
ho trovato ed adeguato alle mie esigenze la seguente macro:


Sub Elimina_righe_zero()
'
Dim r, c, x

r = Cells(Rows.Count, 5).End(xlUp).Row
For x = r To 2 Step -1
If Cells(x, 5) = 0 Then
Rows(x & ":" & x).Select
Selection.Delete Shift:=xlUp
End If
Next x
End Sub


Detta macro svolge il suo compito, ma impiega circa 2 minuti(!) a scorrere 500 righe all'incirca (probabilmente è poco meno del il tempo che impiegherei con cancellazioni manuali...)
Mi sapete indicare (e correggere) la causa di questa lentezza?
Grazie

[Marius44]

Ciao
Prova a "ridurre" la tua macro così

Codice: Seleziona tutto

Sub Elimina_righe_zero()
'
Dim r as long,  x as long

r = Cells(Rows.Count, 5).End(xlUp).Row
For x = r To 2 Step -1
  If Cells(x, 5) = 0 Then Rows(x & ":" & x).Delete Shift:=xlUp
Next x
End Sub


Fai sapere. Ciao,
Mario

[Anthony47]

Col suggerimento di Mario certamente otterrai un notevole miglioramento, ma se ora impiega 2 minuti per 500 righe probabilmente c'e' ancora qualche altra causa, oltre all'inutile Select che Mario ti ha eliminato; probabilmente formule complesse (che si ricalcolano a ogni cancellazione riga) o "eventi" che si innescano su questi cambiamenti.
Io quindi aggiungerei quindi le classiche istruzioni che modificano le modalita' di calcolo, di ScreenPpdate e di gestione eventi; cioe:

Codice: Seleziona tutto

Sub Elimina_righe_zero2()
'
Dim r As Long, x As Long
'
Application.Calculation = xlCalculationManual
Application.ScreenUpdating = False
Application.EnableEvents = False
r = Cells(Rows.Count, 5).End(xlUp).Row
For x = r To 2 Step -1
  If Cells(x, 5) < 12 Then Rows(x & ":" & x).Delete Shift:=xlUp
Next x
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True
Application.EnableEvents = True
Application.Calculate
End Sub


Ciao a tutti

[libraio]

Grazie Anthony,
ho applicato la tua macro: perfetta e veloce come un fulmine.
Un tributo anche alle tue capacità "divinatorie"... effettivamente le colonne B,C,D, e la stessa E contengono funzioni che (come hai intuito).
Un saluto riconoscente

[ikwae]

ciao a tutti... questa macro è "Manna dal Cielo" per le mie ricerche quindi in ordine ringrazio il libraio per aver proposto il
problema Marius44 come "Pioniere" della macro e infine Anthony per "l'alta velocità" ... cordialmente ikwae

[Anthony47]

Grazie Anthony,
ho applicato la tua macro: perfetta e veloce come un fulmine.

La "mia" macro e' in realta' quella di Mario, che e' derivata dalla tua; quindi piu' che altro un lavoro di squadra.
Quanto alle capacita' divinatorie, beh anche un Pc di 20 anni fa non impiega "minuti" per riulire un elenco di 500 righe, era evidente che c'era un problema di ricalcolo o forse di eventi.

Lieto che serva anche ad altri; ma con migliaia e migliaia di righe la lentezza tornera', e bisognera' cambiare approccio...