confrontare due clonne excel e aggiungere mancanti

[libraio]

Ciao a tutti,
ancora una volta mi affido al vostro prezioso aiuto.
Ho un elenco di nominativi in colonna A di due fogli diverdi (Foglio1 e Foglio2)
In Foglio2 i nominativi vengono periodicamente implementati; confrontati i nominativi presenti nelle due colonne, vorrei che i nominativi mancanti nel Foglio1 venissero agggiunti per accodamento (dalla prima cella libera).

Esempio:

Codice: Seleziona tutto

Foglio1     Foglio2
A              A
B              B
C              C
D              D
                AA
                BA

Accodare 'AA' e 'BA' all'elenco in Foglio1.
s.o. Windows 7 + Excel 2003
Si può fare? (cit. Frankenstein Junior...)
Grazie

Edit:
Aggiunto Tag "Code", che rende il msg leggibile
Anthony

[libraio]

Chiuso il post, ho visto che l'esempio risulta illeggibile...
Lo ripropongo:
Foglio1
Colonna A
A
B
C
D

Foglio2
Colonna A
A
B
C
D
AA
BA

Vorrei che dal confronto venisse aggiunto in coda al foglio1
AA
BA

Grazie

[Anthony47]

Anche il primo messaggio sarebbe stato leggibile, se avessi usato il tag "code" per la tabella dati (come ho poi fatto io)

Probabilmente questa macro fara' quel che chiedi:

Codice: Seleziona tutto

Sub Allinear()
Dim Allinea As Worksheet, Allineator As Worksheet
Dim I As Long, ckCol As String, LastCk As Long, addCnt As Long
'
Set Allinea = Sheets("Foglio1")         '<<< Il foglio da allineare
Set Allineator = Sheets("Foglio2")      '<<< Il foglio con possibili nuovi valori
ckCol = "A"                             '<<< La colonna da Controllare /Aggiornare
'
LastCk = Allinea.Cells(Rows.Count, ckCol).End(xlUp).Row
For I = 1 To Allineator.Cells(Rows.Count, ckCol).End(xlUp).Row
    If IsError(Application.Match(Allineator.Cells(I, ckCol).Value, Allinea.Cells(1, ckCol).Resize(LastCk + addCnt, 1), False)) Then
        addCnt = addCnt + 1
        Allinea.Cells(LastCk + addCnt, ckCol).Value = Allineator.Cells(I, ckCol).Value
    End If
Next I
MsgBox ("Completato, " & addCnt & " aggiunte")
End Sub

Le righe marcate <<< sono da compilare come da commento

Ciao

[libraio]

Grazie Anthony,
è perfetto!