somma di codici in piu fogli e in un periodo

[raimea]

ciao

tramite macro vorrei fare delle somme di vari codici
sparsi su piu fogli, in un periodo specificato, per un mese.

nel fgl >>> gen_settori in colonna D8
indico quali fogli sono da analizzare,
questo sara' variabile, quindi da verificare ogni volta.


1_ contare i tecnici di tale foglio e riportarlo in col E8
i nominativi da contare sono sempre da col D3 di ogni foglio

2_ considerando la prima data di cella H7 di fgl gen_settori
fare la somma per ogni giorno
dei codici sparsi nei fogli indicati in col D8

i codici da cercare sono :
B_1_2_LL_RI_FI_SP

i risultati della somma per ogni giorno, di ogni codice
sono da riportare da riga 8 a righe "alterne".

vi allego il file

https://www.dropbox.com/s/sdvqhpcm3225onz/tutti_fogli.rar?dl=0

ciao

[Anthony47]

Per la compilazione del numero dei tecnici, usa in E8 la formula

Codice: Seleziona tutto

=SE(D8<>"";CONTA.VALORI(INDIRETTO("'"&D8&"'!D3:D1000"));0)

Poi copia verso il basso

Per la compilazione del tabellone di riepilogo, questa macro smuove un po' di dati, ma devi fare un collaudo piu' attendibile del mio

Codice: Seleziona tutto

Sub MultiMese()
Dim iMese As String, iSh As String, iData As Date, cArr, cData As Date
Dim ckMon As Worksheet, oSh As Worksheet, hPos, vPos
Dim I As Long, J As Long, K As Long
'
Application.ScreenUpdating = False
iMese = "H7"
iSh = "D8"
cArr = Array("B", "1", "2", "LL", "RI", "FI", "SP")
Set oSh = Sheets("gen_settori")
iData = oSh.Range("H7").Value
For I = 1 To (UBound(cArr) + 1) * 2 Step 2
    Debug.Print oSh.Range(iMese).Offset(I, 0).Resize(1, 31).Address
    oSh.Range(iMese).Offset(I, 0).Resize(1, 31).ClearContents
Next I
For I = 1 To Application.WorksheetFunction.CountA(oSh.Range(iSh).Resize(20, 1))
    Set ckMon = Sheets(oSh.Range(iSh).Offset(I - 1, 0).Value)
    For J = 1 To 31
        hPos = Application.Match(CLng(iData + J - 1), ckMon.Range("A2").Resize(1, 500), False)
        If Not IsError(hPos) Then
            For K = 3 To ckMon.Cells(Rows.Count, hPos).End(xlUp).Row
                vPos = Application.Match(ckMon.Cells(K, hPos).Value, cArr, False)
                If Not IsError(vPos) Then
                    oSh.Cells(7 + vPos * 2 - 1, 7 + J).Value = oSh.Cells(7 + vPos * 2 - 1, 7 + J).Value + 1
                End If
            Next K
        End If
    Next J
    DoEvents
Next I
Application.ScreenUpdating = True
MsgBox ("Completato...")
End Sub


Prova...

[raimea]

ciao

e' PERFETTA

tutto ok

Grazie