Scadenzario dinamico - Excel

[franco595955]

Ciao a tutti. Ho un problema con una formula di excel per gestire una sorta di previsionale di incasso. Ho una riga con una serie di importi che rappresentano le fatture da incassare, ogni colonna è un mese. Vorrei che sulla base di un valore di scadenza (esempio 30gg oppure anche 1, 2, 3) su un'altra riga tutti gli importi vengano sfalsati di quel valore. Inserisco una tabella:

Codice: Seleziona tutto

---------Gen   Feb   Mar   Apr   Mag   Giu   Lug
Fatture  250   150   120   260   253     0     0
Incasso    0   250   150   120   260   253     0

gg pag 30

In pratica se in gg di pagamento inserisco 60, voglio che tutto scali di due mesi, quindi il primo incasso me lo dovrebbe mostrare a Marzo e così via, prevedendo che al massimo si possa arrivare a 180gg di ritardo. Spero di essere stato chiaro.
Grazie dell'aiuto e auguri a tutti.
Franco

[Anthony47]

Intanto "Benvenuto nel forum"

Quanto al quesito come l'hai posto, si potrebbe usare la funzione SCARTO; ad esempio, con riferimento alla prima immagine:


in E3 inserire la formula

Codice: Seleziona tutto

=SE.ERRORE(SCARTO(E2;0;-INT($A$4/30))*1;"")

Copia poi verso destra

Potresti pero' valutare una opzione piu' articolata, che consenta l'impostazione della scadenza fattura per fattura. Ad esempio, con riferimento alla seconda immagine:

In E7 inserisci la formula

Codice: Seleziona tutto

=SE(MESE(DATA.MESE($B7;INT($D7/30))+1)=MESE(E$1);$C7;0)

Poi copia verso destra; poi copia la prima riga di formule verso il basso

Sulla riga 6 puoi calcolare il totale del mese; in E6

Codice: Seleziona tutto

=SOMMA(E7:E1000)

Poi copia verso destra

In questo caso e' importante che in riga 1 ci sia una data; io ho inserito in E1 la data di partenza, poi in F1:

Codice: Seleziona tutto

=FINE.MESE(E1;0)+1

Copia poi la formula verso destra

Il tutto e' dimostrato nel file scaricabile qui: https://www.dropbox.com/s/ds0g03je6hzw1 ... .xlsx?dl=0

Ciao

[franco595955]

Grazie Antony47, tutto perfetto come al solito, le tue soluzioni sono sempre impeccabili.