LEGGERE I DATI DA COLONNA AU

[giorgioa]

Salve

Codice: Seleziona tutto

Sub Somma90()
Dim I As Integer, J As Integer, K As Integer, L As Integer
Dim R As Integer
'
For I = 6 To Cells(Rows.Count, "C").End(xlUp).Row
    L = 9
    For J = 1 To 4
        For K = J + 1 To 5
            R = Cells(I, J + 2) + Cells(I, K + 2)
            If R > 90 Then R = R - 90
            Cells(I, L) = R
            L = L + 1
        Next K
    Next J
Next I
End Sub

questo codice è stato scritto su una richiesta,
Ora succede che lo stesso codice mi faccia calcolo su un'altra posizione del foglio e anche i dati si trovano su altra posizione

quello che ho capito:
for i = 6 to cell.... passa a For i = 4 to cells scrivere su rigo 4;
L = 9 passa a L = 52 (colonna AZ) che mi riporta il calcolo da colonna 52.53 3cc
non riesco a decifrare
questo codice calcola colonna: C-D-E-F-G mentre vorrei che il calcolo faccia su colonna:AU-AV-AW-AX-AY (47-48-49-50-51)

[Marius44]

Ciao
Innanzi tutto la dichiarazione delle variabili della prima riga deve essere Long (altrimenti costringi Excel a fare una conversione); le righe e le colonne sono sempre valori Long.
Se ho capito bene, per calcolare i dati delle colonne che ti servono basta cambiare la lettera C in AU, cioè

Codice: Seleziona tutto

For I = 6 To Cells(Rows.Count, "AU").End(xlUp).Row

Ciao,
Mario

[Anthony47]

Ciao Mario,
In aggiunta alla tua modifica credo ci sia anche da modificare quei "2" in R = Cells(I, J + 2) + Cells(I, K + 2), che credo debbano diventare "46"

@giorgioa
E se non risolvessi con queste informazioni allora puo’ essere utile che rispieghi dove si trovano ora i dati di partenza e dove vanno scritti i risultati

[giorgioa]

Salve Anthony

RISOLTO

il problema

+ che altro mi serve per capire il comportamento del codice
Grazie Marius, grazie Anthony

[Anthony47]

+ che altro mi serve per capire il comportamento del codice

Ho aggiunto qualche commento al codice:

Codice: Seleziona tutto

Sub Somma90()
Dim I As Integer, J As Integer, K As Integer, L As Integer
Dim R As Integer
'
For I = 6 To Cells(Rows.Count, "C").End(xlUp).Row       'I indirizza le righe
    L = 9                                               'La colonna iniziale per i risultati; 9=I
    For J = 1 To 4                                      'J indirizza il primo dei numeri da sommare
        For K = J + 1 To 5                              'K indirizza il secondo
            R = Cells(I, J + 2) + Cells(I, K + 2)       'La somma tra 1° e 2° numero
            If R > 90 Then R = R - 90                   'Si "riduce" a 90
            Cells(I, L) = R                             'Si scrive su colonna
            L = L + 1                                   'Si incrementa la colonna
        Next K                                          'Avanti col 2° numero
    Next J                                              'Avanti col 1° numero
Next I                                                  'Avanti con la riga
End Sub


Come ti ha già suggerito Mario, le variabili numeriche che fanno riferimento a Righe e' necessario siano di tipo Long, non Integer (ci sono piu' di 32mila righe in un foglio); le altre numeriche intere e' meglio se sono di tipo Long (io uso sempre Long perchè una leggenda metropolitana dice che il vba è ottimizzato per questo tipo di dati)

[giorgioa]

Grazie Anthony

è quello che volevo sapere

Buona giornata