EXCEL Istruzioni per CREARE UN CALENDARIO

[marte1503]

Ciao a tutti,
metto a disposizione della rete le istruzioni trovate sul mio libro per creare un comodissimo calendario all’interno di un foglio EXCEL.
Istruzioni:

- Selezionare l’intervallo B2:H2 e unire le celle scegliendo Home > Allineamento > Unisci e centra
- Inserire una data nell’intervallo unito (il giorno del mese non è importante)
- Inserire i nomi abbreviati dei giorni (Lun Mar eccetera) nell’intervallo B3:H3 (B3 è DOMENICA, e trascinare verso destra per creare gli altri giorni)
- Selezionare l’intervallo B4:H9 e inserite questa formula per matrici da confermare con Ctrl+Maiusc+Invio

=SE(MESE(DATA(ANNO(B2);MESE(B2);1))<>MESE(DATA(ANNO(B2);MESE(B2);1)-(GIORNO.SETTIMANA(DATA(ANNO(B2);MESE(B2);1))-1)+{0\1\2\3\4\5}*7+{1;2;3;4;5;6;7}-1);"";DATA(ANNO(B2);MESE(B2);1)-(GIORNO.SETTIMANA(DATA(ANNO(B2);MESE(B2);1))-1)+{0\1\2\3\4\5}*7+{1;2;3;4;5;6;7}-1)

- Formattare l’intervallo B4:H9 con un formato personalizzato: g

Cambiando il mese o l’anno in B2 il calendario si aggiornerà automaticamente.

Bye

[raimea]

mamma mia...
non potresti anche allegare un piccolo file con
gia inerito tutto cio ?
tanto per dare un aiutino ai piu imbranati come me...
ciao grazie

puoi appoggiare il file qui:

http://www.sendspace.com/

[marte1503]

Ciao Raimea

Provo ad allegare il file, non l'ho mai fatto spero vada tutto ok!

Il file è migliorabile io ci voglio lavorare un po'...

http://www.sendspace.com/file/j2vu2g

[raimea]

okkk
ben fatto
hai allegato correttamente,
ho scaricato il file mo me lo guardo con calma su come e' fatto.
grazie

[Anthony47]

E se preferite rappresentare la settimana da Lunedi' alla Domenica (invece che da Domenica a Sabato), usate la formula

Codice: Seleziona tutto

=SE(MESE(DATA(ANNO(B2);MESE(B2);1))<>MESE(DATA(ANNO(B2);MESE(B2);1)-(GIORNO.SETTIMANA(DATA(ANNO(B2);MESE(B2);2))+4)+{0\1\2\3\4\5}*7+{1;2;3;4;5;6;7}-1);"";DATA(ANNO(B2);MESE(B2);1)-(GIORNO.SETTIMANA(DATA(ANNO(B2);MESE(B2);2))+4)+{0\1\2\3\4\5}*7+{1;2;3;4;5;6;7}-1)


Sempre Contr-Maiusc-Enter
Ovviamente cambiate anche le intestazioni i riga 3....

Grazie e marte1503 che ha voluto sharare il suo esercizio.


Attenzione, modificata formula

[raimea]

mamma mia questi computer...
io uso office 2003..
ho provato a realizz il calendario ma niente , le caselle dei giorni rimangono bianche...
premetto che il calend di marte1503 mi funziona,
solo che ogni volta che lo apro/chiudo mi fa la conversione.

volevo farne uno io con off '03 proprio x evitare cio.
vi allego il mio "compito"...

http://www.sendspace.com/file/fpemlw

[marte1503]

Ciao Anthony!

Ho appena risistemato il calendario con partenza settimana da lunedì (così ha un aria un po' più "nostrana"), lo preferisco. Mi sono accorto però, che ora inserendo la tua formula (giusta nei risultati) c'è un problema.
prova a inserire il mese di febbraio, vedrai che i giorni inspiegabilmente partono dalla seconda riga piuttosto che dalla prima. me lo puoi sistemare?

Grazie (non ci provo io perchè non so nemmeno dove mettere mano...)

Seconda cosa:

in cella A1 (quindi in una zona morta del foglio) ho inserito la funzione =adesso()
in cella A2 =giorno(A1) ottenendo 26
ho provato a selezionare l’intervallo contenente i giorni (risultato della matrice) e ho attivato la formattazione condizionale con riferimento a A2 =A2 Formato personalizzato Riempimento VERDE sperando di colorare il giorno in questione cioè oggi di Verde ma non funziona…
Cosa sbaglio?

Se non è una complicazione eccessiva:
si può fare in modo che venga colorato di VERDE lo sfondo solo se corrisponde anche il mese?
In pratica oggi 26 Gennaio deve essere verde, ma nel caso andassi a Febbraio la formattazione non deve evidenziare il 26 (lo so, roba da pignolini… sono un po’ rognoso… )
Aspetto consigli
Grazie

[Anthony47]

Per Raimea: Devi selezionare 6 righe (es B4:H9) in cui incollare la formula.
Tuttavia mi sono reso conto che la formula che io ho dato e' errata, come segnala anche marte1503; quella (spero) giusta e'

Codice: Seleziona tutto

=SE(MESE(DATA(ANNO(B2);MESE(B2);1))<>MESE(DATA(ANNO(B2);MESE(B2);1)-(GIORNO.SETTIMANA(DATA(ANNO(B2);MESE(B2);1);2)-1)+{0\1\2\3\4\5}*7+{1;2;3;4;5;6;7}-1);"";DATA(ANNO(B2);MESE(B2);1)-(GIORNO.SETTIMANA(DATA(ANNO(B2);MESE(B2);1);2)-1)+{0\1\2\3\4\5}*7+{1;2;3;4;5;6;7}-1)


Per quanto riguarda la formattazione condizionale, seleziona l' intera area del calendario (es B4:H9), e applica la formattazione condizionale con le clausole:
Il valore della cella e'; uguale a; =OGGI()
Infatti anche se nelle celle "vedi" il numero del giorno questo e' per effetto della formattazione applicata, che (come e' noto) modifica l' aspetto non la sostanza dei dati, e quelle celle contengono infatti una data.

Ciao

[raimea]

Per Raimea: Devi selezionare 6 righe (es B4:H9) in cui incollare la formula

fatto ma le celle con off.'03 rimangono bianche senza nessun numero, (data).

[Anthony47]

Secondo me tu scrivi a formula in B4, poi la copi nelle altre celle; questo e' sbagliato, nella circostanza.
Seleziona tutte le celle, nella barra della formula scrivi la formula, Contr-Maiusc-Enter
Oppure, scritta la formula in B4, selezioni tutte le celle (B4:H9), tasto F2, Contr-Maiusc-Enter

Ciao

[raimea]

Secondo me tu scrivi la formula in B4, poi la copi nelle altre celle;

confermo..
facevo cosi, non avevo capito che in questo caso si doveva
selez l'area e scrivere la formula nella
barra delle funzioni..

grazie "professore" x la certosina spiegazione...
ora funziona.

[raimea]

sto proseguendo nello svolgimento del "compito"..
ho raliz il calendario, ora vorrei incrementare i mesi,
ma se faccio un somma+1 mi incrementa il giorno non mi scrive il mese,
mi spiego meglio: in B2 scrivo una data es. 2-1-2011,
vorrei che in automatico in B13 diventi febbraio in B24 marzo ecc...
nel file ho messo anche i conteggi dei giorni "lavorativi compreso il sabato".
grazie.

http://www.sendspace.com/file/p59h8p

[Anthony47]

La tua richiesta e' simile a quella avanzata da marte1503 e gestita in questa discussione: viewtopic.php?t=90072

Ciao, fai sapere.

[raimea]

ho letto il post sopra riportato,
ma li', si vuole applicare una macro ,
io pensavo di risolvere senza una macro ne barre a scorrimento.
sempicemente scrivendo una data in B2, le celle B13 B24 ecc..
in automatico si incrementino di un mese non come ora che con la formule =B2+1
mi aumenta di 1 giorno.
grazie.

[Anthony47]

Nella discussione che ti ho linkato non c' e' nessuna macro, solo una o due barre di scorrimento per impostare mese e anno.

Vedo pero' che tu vuoi fare una cosa un po' diversa, cioe' un calendario che visualizza gia' N mesi; senza disquisire sull' utilita' di questa realizzazione, metti in B13 la formula

Codice: Seleziona tutto

=FINE.MESE(B2;0)+1

Ma anche la tua impostazione (formula del tipo =B1+31, senza preoccuparsi della durata del mese precedente) e' idonea per almeno 4 anni in avanti.

Ciao

[raimea]

e' prorio la formula che cercavo e non conoscevo.

Codice: Seleziona tutto

=FINE.MESE(B2;0)+1

funziona correttamente proprio come volevo io .
GRAZIE

[raimea]

continuo con il rifinire il calendario.
ora vorrei poter colorare i giorni "festivi" riportati in colonna P2:P13
cioe': se usare una format condiz come impostarla ?
oppure meglio con una macro ?
dato che combiando date-anni in B2 si crea ogni volta un nuovo calendario.
ciao

http://www.sendspace.com/file/yiy4qf

[Anthony47]

Puoi usare una formattazione condizionale con formula:
-selezioni B4:H9 (o B4:H262; vedi nota1)
-imposti la formattazione con "la formula è"
-come formula inserisci =Conta.se(Festivi;B4)>0
-inserisci il formato che preferisci

Ricorda pero' che le date scritte nell' intervallo Festivi devono essere "assolute"; cioe' del tipo "25 aprile 2011", non solo "25 aprile" Per le feste fisse (es 25 aprile) puoi inserire una formula del tipo =data(Anno(B2);4;25) mentre per altre variabili (es lunedi' di Pasqua) devi mettere le date precise anche per gli anni futuri. Per questo non ho usato P2:P13 come intervallo per queste dichiarazioni, ma un intervallo lungo a piacere che chiamerai "Festivi" (lo puoi fare anche lungo 1000, anche se poi ne compili solo 20).
Nota1: in questo modo formatterai anche le intestazioni del mese, col risultato che ad es maggio e novembre saranno intestate come festivi; se ti da' fastidio, rimuovi la formattazione sulle celle di intestazione mese. Oppure cambia la formula in B13 e successive intestazioni in =FINE.MESE(B2;0)+1,01

Ciao

[raimea]

hee heee lo so io che qui c'e solo da imparare....
tutto ok,
sistem anche : festivi fissi, intestazione mesi.
grazie

metto il file nel caso serva a qualcuno.

http://www.sendspace.com/file/rl2d7v

[ricky53]

Ciao,
bel lavoro Raimea.
Attenzione Pasquetta è il 25-04-2011 e non il 24-05-2011 ------>> anche tu sei iscritto all'associazione della "Dislessia grafica"

Comuqnue ti infomro che io sono il presidnente onorairo di quetsa associazoine !!!